!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
!	EXIT				- leave the program
!	GRANT id user-id		- grants this ID to a user
!	GRANT/CONTROL id user-id	- grants the ability to grant and
!					  revoke this ID to a user
!	HELP				- print this text
!	QUIT				- leave the program
!	REVOKE id user-id		- revokes the ID a given user
!	REVOKE/CONTROL id user-id	- removes the ability to grant and
!					  revoke this ID to a user
!	SHOW id				- show who owns this ID
!	SHOW/USER id			- show all the IDs the oper can control
!					   and the user in question posesses
!	SHOW/AUTHORIZED id		- show who is auth'd to change this ID
!	SHOW/IDENTIFIERS		- show what ID's the oper can change
!	SPAWN				- spawn a subprocess
!
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

module iaf_subcommands
ident "V1.01"
!
!	What ID's can I control that this person has?
!

define syntax SHOW_USER
   routine show_user
   parameter P1, label=ID, prompt="UIC"
      value(required, type=$uic)
  
!
!	Who else can control the ID's I can control?
!

define syntax SHOW_AUTH
   routine show_auth
   parameter P1, label=ID, prompt="Identifier"
      value(required, type=$uic)
  
!
!	What ID's can I control?
!
define syntax SHOW_IDENT
   routine show_IDENT
   parameter P1, label=ID
   value(type=$uic)

!
!	Get me out of this!
!

define verb EXIT
   synonym QUIT
   synonym STOP
   routine finis

!
!	Let me grant an ID, or control of an ID to someone
!
define verb GRANT
   routine grant
   parameter P1, label=GRANTED_ID, prompt="ID to grant"
      value(required, type=$uic)
   parameter P2, label=USER_ID, prompt="User ID to grant to"
      value(required, type=$uic)
   qualifier IDENTIFIER
   qualifier LOG, negatable, default
   qualifier CONFIRM, negatable, default
   qualifier CONTROL, negatable, default
   qualifier RESOURCE, negatable, default
   qualifier DYNAMIC, negatable, default
   disallow (control and resource) or (control and dynamic)

!
!	What are the commands?
!
define verb HELP
   routine help
   parameter P1, label=TOPIC
      value(type=$rest_of_line)
   
!
!	Let me grant an ID, or control of an ID to someone
!
define verb REVOKE
   routine revoke
   parameter P1, label=GRANTED_ID, prompt="ID to revoke"
      value(required, type=$uic)
   parameter P2, label=USER_ID, prompt="User ID to revoke from"
      value(required, type=$uic)
   qualifier IDENTIFIER
   qualifier LOG, negatable, default
   qualifier CONFIRM, negatable, default
   qualifier CONTROL, negatable, default

!
!	Let me find out about who controls what
!
define verb SHOW
   routine show_owners
   parameter P1, label=ID, prompt="Identifier"
      value(required, type=$uic)
   qualifier AUTHORIZED, syntax=SHOW_AUTH
   qualifier USER, syntax=SHOW_USER
   qualifier IDENTIFIERS, syntax=SHOW_IDENT
   disallow (any2 (authorized, user, identifiers))

!
!	Spawn a subprocess
!
define verb SPAWN
   routine spawn
   parameter P1, label=COMMAND
   value(type=$rest_of_line)