$!	netsubmit.com
$!		Runs a batch job in SYS$LOGIN: directory of another DECNET node
$!
$ if f$trnlnm("NET_NODE",).eqs.""  then  define net_node uwapa1::
$ if p1.eqs."" then inquire p1 "_File: "
$!	extract user's filename from parameters, even if qualifiers
$ usersfile:="''p1'"
$ loc=f$locate("/",p1)	! =length if no slash
$ if loc.ne.f$length(p1) then  usersfile:="''f$extract(0,loc,p1)'"
$!	add .COM if no filetype
$ copyfile=f$parse(usersfile,".COM",,,"syntax_only")
$ submfile=f$parse(copyfile,,,"name","syntax_only")+ -
           f$parse(copyfile,,,"type","syntax_only")+ f$extract(loc,-1,p1)
$ copy  'copyfile'  net_node::;0   ! copy command file to remote SYS$LOGIN:
$ write sys$output "On node ''f$trnlnm("NET_NODE",)'"
$ atnode net_node:: oneline submit 'submfile' 'p2' 'p3' 'p4' 'p5' 'p6' 'p7' 'p8'
$exit
$!
$!	Inputs:
$!		p1	single command file name and qualifiers
$!		p2...p8	qualifiers
$!
$!	Usage:
$!		NETSUBMIT :== @DRC1:[DECNETWORK.BATCH]NETSUBMIT.COM
$!		DEFINE  NET_NODE  JANUS::
$!		NETSUBMIT  G1FD/QUEUE=FAST$BATCH/NOLOG
$!
$!		submits G1FD.COM from current directory on current node
$!		to JANUS:: queue FAST$BATCH
$!		keeping no .LOG file on that node
$!		with two filenames as parameters to the G1FD.COM command file
$!		
$!
$! /NOTIFY works only if SET HOST via the target node since only
$!   notifies on node where executed
$! should allow /NODE= parameter ?
$!  could take original .COM file
$! May fail on particularly complicated parameters or qualifiers involving
$! symbol translation.   Beware logical names and/or symbols that
$! that are different or not defined on both nodes.
$!