.TITLE DCBLST
	.MCALL EXIT$S,DCBDF$,HWDDF$,QIOW$S
	DCBDF$
	HWDDF$
;
;			MAC DCBLST=[1,1]EXEMC/ML,[7,241]DCBLST
;
;			TKB DCBLST/PR=DCBLST,[1,54]RSX11M.STB/SS
;
DCBLST:	MOV $DEVHD,R3
;
1$:	MOV (R3),R3
	BEQ EXIT
	QIOW$S #IO.WVB,#5,#1,,,,<#CRLF,#2,#0>
	MOV D.UCB(R3),R5
	MOVB D.NAM(R3),DCB
	MOVB D.NAM+1(R3),DCB+1
	CLR UNIT	
	MOVB D.UNIT+1(R3),R4
	MOVB D.UNIT(R3),R2
	INC R4
	SUB R2,R4
2$:	CLR UN
	CLR VECTOR
	CLR VECTOR+2
	CLR VECTOR+4
	CLR CSR
	CLR CSR+2
	CLR CSR+4
	MOV #UN,R0
	MOV UNIT,R1
	CLR R2
	CALL $CBOMG
	BIT #DV.PSE,U.CW1(R5)
	BNE 3$
	MOV #VECTOR,R0
	MOV R5,R1
	MOV U.SCB(R1),R1
	MOV R1,-(SP)
	MOVB S.VCT(R1),R1
	ASL R1
	ASL R1
	CLR R2
	CALL $CBOMG
	MOV #CSR,R0
	MOV (SP)+,R1
	MOV S.CSR(R1),R1
	CLR R2
	CALL $CBOMG
3$:	ADD D.UCBL(R3),R5
	INC UNIT
	QIOW$S #IO.WVB,#5,#1,,,,<#DCB,#DCBLEN,#40>
	DEC R4
	BGT 2$
	BR 1$
;
;
EXIT:	EXIT$S
;
;
CRLF:	.BYTE 15,12
UNIT:	.WORD 0
DCB:	.BYTE 0,0
UN:	.BLKB 6
	.ASCII /: --- VECTOR: /
VECTOR:	.BLKB 6
	.ASCII /   CSR: /
CSR:	.BLKB 6
;
DCBLEN=.-DCB
;
	.EVEN
	.END DCBLST