! XEDT handling (SPAWN etc)
!
! This sets up several keys to interface into XEDT.  
! Note that the macros SPAWN and SPELL both work under MAIL with callable
! EDT, which is rather handy (since MAIL implements the SPAWN command as 
! an XLATE routine in callable EDT).
!
!
! SPAWN macro -- spawn a subprocess
!
clear SPAWN ; find buffer SPAWN
i;change;xlateSP^Zex
find last ; define macro SPAWN
!
! Enable privileges
!
clear PRIV ; find buffer PRIV
i;change;xlatePR^Zex
find last ; define macro PRIV
!
! DCL macro -- execute DCL command, output is placed in buffer
!
clear DCL ; find buffer DCL
i;change;xlate$%\DCL^Zex
i;include XEDT_OUT_MBX:
find last ; define macro DCL
!
! MAIL macro -- enters VMS mail without leaving editing session
!
clear MAIL ; find buffer MAIL
i;change;xlateSP MAIL^Zex
find last ; define macro MAIL
!
! SPELL macro -- Invoke DECspell to check file
!
clear SPELL
find buffer spell
i;set nosummary
i;write xedt_spell.tmp
i;set summary
i;c;br der xlateSP spell xedt_spell.tmp^z ex
i;include xedt_spell.tmp
i;c;xlateSP delete xedt_spell.tmp;*/nolog^z ex
find last
define macro spell
!
! Key definitions:
!       Gold $          execute DCL command, output placed in buffer
!       GOLD \          Change current directory
!       Gold Control D  List current directory into buffer DIR
!       Gold Control L  Load file from directory listing
!
define key gold $ as "xlate$$?*'$ '^z."
define key gold \ as "xlateCD?*'New dir: '^z."
define key gold control D as "()extf=dir;c;brderxlate$$DIR *.*;0/COLUMN=1^Zbrd+2l."
define key gold control L as "()advdl2undll-celi;^zbl-c';'del+cblseliINC ^z-celi =?*'Buffer: '^zcutsr=work dlextdef mac work;work."