$ verify = 'F$VERIFY(0)'
$ GOTO L1$
$!
$! FERMIUSS.BLD
$!
$! Build file to create the user-written system service privileged image
$! (FERMIUSS).  If the TEST option is selected, then the test version
$! (TSTFERUSS) will be made.
$!
$! Modifications:
$!  14-May-83	FJN	Created fom ACNETUSS.BLD
$!=============================================================================
$L1$: xver = F$VERIFY(verify)
$ ON ERROR THEN $ GOTO COMPLETED
$!
$! Image name selected by TEST option
$!
$ image = "FERMIUSS"
$ IF test_version THEN image = "TSTFERUSS"
$!
$! Assemble the sources for the dispatcher modules and the various service
$! modules.
$!
$ IF .NOT.do_compiles THEN $ GOTO SKIP_COMPILING
$ COMPILES  FERMIDISP,USR*  FERMIUSS.OBJ  FERMIUSS.LIS
$!
$ IF .NOT.do_objects THEN $ GOTO SKIP_LIBRARY
$!
$! Create FERMIUSS object library
$!
$ EXPERT
$ LIBRARY/CREATE=BLOCKS=60/OBJECT/LOG  FERMIUSS  FERMIUSS.OBJ
$ NOVICE
$ DELETE  FERMIUSS.OBJ;*
$ PURGE   FERMIUSS.OLB
$ IF .NOT.do_listings THEN $ GOTO SKIP_LIBRARY
$ LIBRARY/OBJECT/LIST=TMP$:FERMIUSS.TML/FULL  FERMIUSS
$ CREATE  TMP$:FORMFEED.TMP

$ APPEND  TMP$:FORMFEED.TMP  FERMIUSS.LIS
$ DELETE  TMP$:FORMFEED.TMP;*
$ APPEND  TMP$:FERMIUSS.TML  FERMIUSS.LIS
$ DELETE  TMP$:FERMIUSS.TML;*
$SKIP_LIBRARY:
$SKIP_COMPILING:
$!
$ IF .NOT.do_links THEN $ GOTO SKIP_LINKING
$!
$ LIBRARY/OBJECT/EXTRACT=FERMI_SYS_DISP/OUTPUT=USSDISP.OBJ  FERMIUSS
$!
$! Now link object modules into the shared privileged FERMIUSS (or TSTFERUSS)
$! image.
$!
$ DO_SLNK/SHAREABLE='image'/PROTECT/NOSYSSHR  SYS$INPUT:/OPTIONS
!
 FERMIUSS/INCLUDE=MISC_USER_SERVICES/LIBRARY,SYS$SYSTEM:SYS.STB/SELECTIVE
!
! Create separate cluster for the transfer vectors and dispatchers.
!
CLUSTER=TRANSFER_VECTOR,,,SYS$DISK:[]USSDISP
!
! Section version is V1.1
!
GSMATCH=LEQUAL,1,1
!
$!
$ DELETE USSDISP.OBJ;*
$!
$SKIP_LINKING:
$ NOMSGS
$ PURGE
$ NOVICE
$!
$ IF .NOT.do_print THEN $ GOTO SKIP_PRINTING
$ IF do_listings.AND.do_map THEN $ PRINT/DELETE  FERMIUSS.LIS,FERMIUSS.MAP
$ IF do_listings.AND.(.NOT.do_map) THEN $ PRINT/DELETE  FERMIUSS.LIS
$ IF (.NOT.do_listings).AND.do_map THEN $ PRINT/DELETE  FERMIUSS.MAP
$SKIP_PRINTING:
$!
$COMPLETED:
$ status = $status
$!
$ xver = 'F$VERIFY(0)'
$ EXIT  status.OR.F$VERIFY(verify)