$ GOTO L1$
$!
$! MOREDEVS.COM
$!
$! Perform additional device and shared memory initializations as part of
$! the system startup.
$!
$!	@SYS$STARTUP:MOREDEVS  opsys  ma780
$!
$! If the opsys parameter is TRUE, then startup of Operational VAX is being
$! done (no printers).  If ma780 parameter is TRUE (default if parameter is
$! NULL), then the MA780 shared memory will be connected.
$!
$! Modification History:
$!  28-Jul-82	FJN	Created from SYSTARTUP.COM
$!  30-Nov-82	FJN	Add /PRINTALL for LXY-21 to do plotting
$!  19-Dec-82	FJN	Setup for parameters
$!=============================================================================
$L1$:
$!
$! Connect Dual PCL11-B controllers
$!
$ RUN SYS$SYSTEM:SYSGEN
LOAD LTDRIVER
CONNECT LTA0 /ADAPTER=UB0 /CSR=%O764202 /VECTOR=%O570
CONNECT LTB0 /ADAPTER=UB0 /CSR=%O764242 /VECTOR=%O600
LOAD LRDRIVER
CONNECT LRA0 /ADAPTER=UB0 /CSR=%O764222 /VECTOR=%O574
CONNECT LRB0 /ADAPTER=UB0 /CSR=%O764262 /VECTOR=%O604
EXIT
$!
$! Connect and intitialize shared memory (can be disabled by parameter)
$!
$! Setup for dynamic pool with blocks of 584 bytes in length (allows for
$! mailbox messages on order of 550 bytes) and 128 blocks.
$! Allow up to 32 common event flag clusters and up to 32 mailboxes.
$! This will still leave about 440 pages (out of 512) available for
$! global sections (default of 32 allowed).
$!
$ IF p2.EQS."" THEN p2 = 1
$ IF .NOT.p2 THEN $ GOTO SKIP_MA780_CONNECT
$ RUN SYS$SYSTEM:SYSGEN
SHARE MPM0 SHRMEM /INIT/POOLBSIZE=584
EXIT
$SKIP_MA780_CONNECT:
$!
$ IF p1 THEN $ EXIT			!No printers on Operational system
$!
$! Setup PRINTER characteristics
$!
$ SET PRINTER LPA0:/LP11
$ SET DEVICE LPA0:/SPOOLED
$!
$ SET PRINTER LPB0:/LP11/LOWERCASE/PRINTALL/NOWRAP/WIDTH=134
$ SET DEVICE LPB0:/SPOOLED
$!
$ EXIT