$ GOTO L1$
$!
$! ACCOUNTS.JOB
$!
$! Batch job to produce reports on system accounts.
$!
$! Modifications:
$!  26-Aug-82	FJN	Created from ACCOUNTS.COM
$!  30-Aug-82	FJN	Provided for Operational/Development system differences
$!  31-Aug-82	FJN	Fixes for Oper/Devl differences
$!=============================================================================
$L1$:
$!
$! Select current system type (Development or Operational) based on the
$! logical name ACNET_NODE (equivalence string DEVL or OPER).
$!
$ what := 'F$LOGICAL("ACNET_NODE")'
$ opsys == what .EQS. "OPER"		!TRUE if Operational System
$ dvsys == what .EQS. "DEVL"		!TRUE if Development System
$!
$!
$! Set default directory to system area and UIC to [1,4]
$!
$ SET PROCESS/PRIVILEGE=SYSPRV
$ SET UIC [1,4]
$ SET DEFAULT SYS$SYSTEM:
$!
$! List accounts from UAF
$!
$ DELETE SYSUAF.LIS;*
$ RUN AUTHORIZE
SHOW DEFAULT
SHOW */BRIEF
LIST *
EXIT
$!
$! Protect against users reading the UAF listing
$!
$ SET PROTECTION=WORLD SYS$SYSTEM:SYSUAF.LIS
$!
$! Print 4 copies for distribution to GORMLEY, STORM, THOMAS, NAGY
$! if running on Development system.
$!
$ IF dvsys THEN $ PRINT SYSUAF.LIS/COPIES=4
$!
$! Print the disk space quotas
$!
$ IF opsys THEN $ GOTO SKIPQ1
$ RUN DISKQUOTA
USE USR$DISK1
SHOW [*,*]
USE USR$DISK2
SHOW [*,*]
EXIT
$SKIPQ1:
$ IF dvsys THEN $ GOTO SKIPQ2
$ RUN DISKQUOTA
USE OP$USR1
SHOW [*,*]
EXIT
$SKIPQ2:
$!
$! Re-make the USERLIST.DAT and ALLUSERS.DIS files
$!
$ SET DEFAULT SYS$MANAGER:
$!
$ verify = 'F$VERIFY(0)'
$@SYS$MGR_UTIL:SCNUAFLIS
$ IF verify THEN SET VERIFY
$!
$ TYPE USERLIST.DAT
$!
$! Update the quota restoration files
$!
$ SET DEF SYS$MGR_UTIL:
$ user_disk_1 = "USR$DISK1  USRDISK1.COM"
$ IF opsys THEN user_disk_1 = "OP$USR1  OPUSR1.COM"
$@DISKQUOTA  'user_disk_1'
$ IF dvsys THEN $@DISKQUOTA  USR$DISK2  USRDISK2.COM
$ NOMSGS
$ PURGE USRDISK*.COM,OPUSR*.COM
$ NOVICE
$!
$! All done
$!
$ EXIT