$ GOTO L1$
$!
$! BIGBROTHR.JOB
$!
$! Job run once a week to extract from the current accounting file a list of
$! the system initializations and login failures for the past week.  These
$! reports are left in SYS$SYSDEVICE:[MONITORIN] as files SYSINITS.WKY and
$! LOGFAILS.WKY respectively.  On the Development System, these files are
$! printed.
$!
$! Modifications:
$!  05-Sep-82	FJN	Created to watch the system for suspicious activity
$!  06-Sep-82	FJN	Fix device in PRINT commands
$!=============================================================================
$L1$:
$ verify = 'F$VERIFY(0)'
$!
$! Select current system type (Development or Operational) based on the
$! logical name ACNET_NODE (equivalence string DEVL or OPER).
$!
$ what = F$LOGICAL("ACNET_NODE")
$ opsys == what .EQS. "OPER"
$ dvsys == what .EQS. "DEVL"
$!
$ SET PROCESS/NAME=BIGBROTHER		!Process name for grins
$ IF verify THEN $ SET VERIFY
$!
$! Delete any old .LOG files of this job
$!
$ PURGE BIGBROTHR.LOG
$!
$! Now make the reports of system initializations and login failures from
$! the current accounting file but only for the previous week.
$!
$ ACC_WEEK := ACCOUNTING/BEFORE=TODAY/SINCE="TODAY-7-00:00"
$ ACC_WEEK/TYPE=SYSINIT/OUTPUT=SYS$SYSDEVICE:[MONITORIN]SYSINITS.WKY
$ ACC_WEEK/TYPE=LOGFAIL/OUTPUT=SYS$SYSDEVICE:[MONITORIN]LOGFAILS.WKY
$!
$ IF opsys THEN $ EXIT			!No printers on Operational system
$ PRINT  SYS$SYSDEVICE:[MONITORIN]SYSINITS.WKY
$ PRINT  SYS$SYSDEVICE:[MONITORIN]LOGFAILS.WKY
$ EXIT