.;
.; CLNSYSGEN.CMD
.;
.; May be called with parameters such that p1=name of device with target
.; system disk and p2=name of device with EXCPRV/RLUTIL disk.
.;
.ENABLE SUBSTITUTION
;
; This command procedure is used to cleanup the RSX-11M distribution
; disks after doing a SYSGEN.  It also permits one to copy some of the
; command files build during SYSGEN onto your target disk for saving.
;
.TEST p1
.IF <STRLEN> NE 0 .GOTO GOTP1
.ASKS p1 Device with target system disk (ddu:)
.TEST p1
.GOTP1:	.IF p1[<STRLEN>:<STRLEN>] NE ":" .SETS p1 p1+":"
.TEST p2
.IF <STRLEN> NE 0 .GOTO GOTP2
.ASKS p2 Device with distribution kit disk (volume EXCPRV or RLUTIL) (ddu:)
.TEST p2
.GOTP2:	.IF p2[<STRLEN>:<STRLEN>] NE ":" .SETS p2 p2+":"
.ASK which Cleaning volume EXCPRV
.IFF EXCPRV .GOTO RLUTIL
.ASK mount Has EXCPRV been software mounted on 'p2'
.IFF mount MOU 'p2'EXCPRV
;
; Moving files from and cleaning EXCPRV disk.
;
SET /UIC=[12,24]
PIP 'p1'='p2'MCRSETASM.CMD
PIP 'p2'MCRSETASM.CMD;*/DE/NM
SET /UIC=[11,24]
PIP 'p1'='p2'RSXASM.CMD,RSXDRVASM.CMD
PIP 'p2'RSXASM.CMD;*/DE/NM,RSXDRVASM.CMD;*
SET /UIC=[11,10]
PIP 'p1'='p2'SYSTB.MAC
PIP 'p2'SYSTB.MAC;*/DE/NM
SET /UIC=[1,24]
PIP 'p2'MCR.OLB/CD='p2'MCR.OLS
PIP 'p2'MCR.OLB/PU
;
; The .CMD and .ODL files from the privileged task builds may
; be copied from EXCPRV to the target system disk.
;
.ASK which Copy .CMD and .ODL files to target system disk
.IFT which PIP 'p1'='p2'*.CMD,*.ODL
PIP 'p2'*.CMD;*/DE/NM,*.ODL;*,MCR.OBJ;*
PIP 'p2'ICBLD.CMD/CD='p2'ICBLD.CMS
PIP 'p2'IPBLD.CMD/CD='p2'IPBLD.CMS
PIP 'p2'ISBLD.CMD/CD='p2'ISBLD.CMS
PIP 'p2'UDCBLD.CMD/CD='p2'UDCBLD.CMS
;
; EXCPRV being dismounted, remove volume from drive.
;
DMO 'p2'
.;
.IF <SYSTEM> EQ 5 EXIT
.EXIT
.;
.RLUTIL:
.ASK mount Has RLUTIL been software mounted on 'p2'
.IFF mount MOU 'p2'RLUTIL
;
; Moving files from and cleaning RLUTIL disk.
;
SET /UIC=[1,24]
;
; The .CMD and .ODL files from the non-privileged task builds may
; be copied from RLUTIL to the target system disk.
;
.ASK which Copy .CMD and .ODL files to target system disk
.IFT which PIP 'p1'='p2'*.CMD,*.ODL
PIP 'p2'*.CMD;*/DE/NL,*.ODL;*
;
; RLUTIL being dismounted, remove volume from drive.
;
DMO 'p2'
.;
.IF <SYSTEM> EQ 4 EXIT
.EXIT