.;
.; RSXSYSGEN.CMD
.;
.;	Used to make the logical name assignments to do an RSX SYSGEN
.;	on the VAX under VMS.  From the VAX-11/RSX-11M USER''S GUIDE
.;
.; Modification History:
.;
.;  01-Jul-81	FJN	Make sure MAC used from SYS$SYSTEM:
.;  03-Jul-81	FJN	Straighten out assignments and
.;			make sure utilities used from SYS$SYSTEM
.;  05-Jul-81	FJN	Use BIGTKB.TSK on SYS$SYSTEM:
.;  25-Jan-82	ADT/KJC	Modify message concerning spooled maps
.;			and the MOU/SHARE command for clarity.
.;  08-Jul-82	FJN	Ask question re RSX V4.0 SYSGEN to use xxx4.TSK
.;			utilities on VAX system disk instead of V3.2 forms.
.;
.ENABLE SUBSTITUTION
.;
.; Get RSX target device if not entered as a parameter
.;
.IF P1 EQ "" .ASKS P1 Target device name
.;
.; Make sure the device name is ended by a colon
.;
.SETS TEMP P1[<STRLEN>:<STRLEN>]
.IF TEMP NE ":" .SETS P1 P1+":"
SHOW SYMBOL P1
.;
.; Set default to target device
.;
SET DEFAULT 'P1'
.;
.; Assign SY, SY0, LB, and LB0 to target disk
.;
ASN 'P1'=SY:
ASN SY:=SY0:
ASN 'P1'=LB:
ASN LB:=LB0:
.;
.; Equates MP0 and MP, also TK0 and TK
.;
ASN MP:=MP0:
ASN TK:=TK0:
.;
.; If doing RSX V4.0 SYSGEN, use different assignments for utilities.
.;
.ASK V4 Doing an RSX-11M V4.0 SYSGEN
.IFT V4 .GOTO RSX4
.;
.; Assigns equivalence names for TKB and VMR
.; BIGTKB.TSK was directly copied from an RSX system.
.;
ASN SYS$SYSTEM:BIGTKB.TSK=TKB
ASN SYS$SYSTEM:VMR=VMR
.;
.; Make sure utilities used from SYS$SYSTEM:
.;
ASN SYS$SYSTEM:MAC=MAC
ASN SYS$SYSTEM:EDT=EDT
ASN SYS$SYSTEM:LBR=LBR
ASN SYS$SYSTEM:PIP=PIP
.;
.; Set process privileges needed to do a SYSGEN
.;
SET PROCESS/PRIVILEGES=(SYSPRV,LOG_IO,CMKRNL)
;
; Note that the baseline system TKB is used.   The maps cannot be sent
; to a non-RSX device or to magtape.  They may be put on the target
; disk ('P1').  It must be mounted SHARE'd to allow the maps to be 
; spooled to the printer:
;
;	> MOU/SHARE 'P1'RSXM26
;	> SET /UIC=[200,200]
;	> @SYSGEN
;
EXIT
.;
.; What follows is specific for V4.0 gens
.;
.RSX4:
.;
.; Assigns equivalence names for utilities kept on VAX system disk (to allow
.; speedier overlays).  Note that these were copied/built from RSX baseline
.; system or RSX system libraries and cannot reference VAX/VMS device and
.; directory names.
.;
ASN SYS$SYSTEM:TKB4.TSK=TKB
ASN SYS$SYSTEM:VMR4.TSK=VMR
ASN SYS$SYSTEM:MAC4.TSK=MAC
ASN SYS$SYSTEM:LBR4.TSK=LBR
ASN SYS$SYSTEM:PIP4.TSK=PIP
.;
.; Use EDT from VAX/VMS system disk (native mode)
.;
ASN SYS$SYSTEM:EDT=EDT
.;
.; Set process privileges needed to do a SYSGEN
.;
SET PROCESS/PRIVILEGES=(SYSPRV,LOG_IO,CMKRNL)
;
; Note that the baseline system MAC and TKB are used.   The listings
; and maps cannot be sent to a non-RSX device or to magtape.  The maps
; may be put on the target disk ('P1').  The assembly listings may be
; placed on a scratch disk (RL01/RL02).  Each disk must be mounted
; SHARE'd to allow the printouts to be spooled to the printer:
;
;	> MOU/SHARE DL2:LISTINGS
;	> MOU/SHARE 'P1'RSXM32
;	> SET /UIC=[200,200]
;	> @SYSGEN
;
EXIT