.TITLE     Send Delay

          ;Title:    Send Delay
          ;
          ;Author:   Seth Stern
          ;Date:     21 March 1982
          ;
          ;Function:
          ;          Pass the user supplied time delay to the mailbox
          ;          established by VT100_CLEAR.  This disables screen
          ;          clearing for the time specified.
          ;
          ;Restrictions:
          ;          VT100_CLEAR must have established the mailbox.
          ;          The user must have write access to the mailbox.


          .PAGE
          .PSECT     DATA

MBX_NAME: .ASCID     'VT100_CLEAR'
MBX_CHAN: .BLKL      1

BUFLEN =  64
TIMEDESC: .LONG      BUFLEN,TIME			;Homebrew descriptor
TIME:     .BLKB      BUFLEN
TIME_LEN: .BLKW      1

PROMPT:   .ASCID     'Time delay: '



          .PAGE
          .PSECT     CODE

          ;*** Start of main program ***

          .ENTRY     SEND,^M<>

          $ASSIGN_S  DEVNAM=MBX_NAME,CHAN=MBX_CHAN
          BLBS       R0,10$
          $EXIT_S    R0

10$:      PUSHAL     TIME_LEN
          PUSHAL     PROMPT
          PUSHAL     TIMEDESC
          CALLS      #3,LIB$GET_FOREIGN			;Get delay
          BLBS       R0,20$
          $EXIT_S    R0

20$:      $QIOW_S    EFN=#1,CHAN=MBX_CHAN,FUNC=#IO$_WRITEVBLK,-
                     P1=TIME,P2=TIME_LEN
          BLBS       R0,30$
          $EXIT_S    R0

30$:      $EXIT_S    #SS$_NORMAL

          .END       SEND