;	PARSER STATE TABLE FOR NETSPEC UTILITY

;	NETSPEC FORMAT:
;		NETSPEC[/ALL/SAMEPASSWORD] [NODE1 NODE2...NODE8]

	$TPADEF		; DEFINE TPA OFFSETS

	$INIT_STATE	PARSE_STATE,PARSE_KEY

	$STATE	START
	$TRAN	'/',QUALIFIERS
	$TRAN	TPA$_STRING, START, MATCHNODE
	$TRAN	TPA$_EOS,TPA$_EXIT

	$STATE	QUALIFIERS
	$TRAN	'ALL', START, ALLNODES
	$TRAN	'SAMEPASSWORD', START, SAMEPASS


	$END_STATE

;	BIT MASKS FOR SWITCHES

	ALL	=	^X1FFF
	SAME	=	^X80000000

KEYVALUE:	.LONG	0
;	KEY TABLE FOR NODE NAMES

KEYTABLE::
	.LONG	MAXNODES*2		; LONGWORD COUNT OF TABLE
	.LONG	NODENAMES		; ADDR OF 1ST NODE NAME
	.LONG	1			; BIT MASK FOR NODE
	.LONG	NODENAMES+<MAXCHARS*1>
	.LONG	2
	.LONG	NODENAMES+<MAXCHARS*2>
	.LONG	4
	.LONG	NODENAMES+<MAXCHARS*3>
	.LONG	8
	.LONG	NODENAMES+<MAXCHARS*4>
	.LONG	^X10
	.LONG	NODENAMES+<MAXCHARS*5>
	.LONG	^X20
	.LONG	NODENAMES+<MAXCHARS*6>
	.LONG	^X40
	.LONG	NODENAMES+<MAXCHARS*7>
	.LONG	^X80
	.LONG	NODENAMES+<MAXCHARS*8>
	.LONG	^X100
	.LONG	NODENAMES+<MAXCHARS*9>
	.LONG	^X200
	.LONG	NODENAMES+<MAXCHARS*10>
	.LONG	^X400
	.LONG	NODENAMES+<MAXCHARS*11>
	.LONG	^X800
	.LONG	NODENAMES+<MAXCHARS*12>
	.LONG	^X1000
	.LONG	NODENAMES+<MAXCHARS*13>
	.LONG	^X2000
	.LONG	NODENAMES+<MAXCHARS*14>
	.LONG	^X4000
	.LONG	NODENAMES+<MAXCHARS*15>
	.LONG	^X8000
	.LONG	NODENAMES+<MAXCHARS*16>
	.LONG	^X10000
	.LONG	NODENAMES+<MAXCHARS*17>
	.LONG	^X20000
	.LONG	NODENAMES+<MAXCHARS*18>
	.LONG	^X40000
	.LONG	NODENAMES+<MAXCHARS*19>
	.LONG	^X80000
ENDTABLE:

;
;	ACTION ROUTINES
;

	.ENTRY	ALLNODES,^M<>
	MOVAL	KEYTABLE+4,R0
10$:	MOVL	(R0)+,R1
	TSTB	1(R1)
	BEQL	20$
	BISL	(R0),NODEMASK
20$:	TSTL	(R0)+
	CMPL	R0,#ENDTABLE
	BNEQ	10$
	MOVL	#1,R0
	RET

	.ENTRY	SAMEPASS,^M<>
	BISL2	#SAME,NODEMASK
	RET

	.ENTRY	MATCHNODE,^M<>

	PUSHAL	KEYVALUE
	PUSHAL	KEYTABLE
	MOVL	AP,R0
	ADDL2	#TPA$L_TOKENCNT,R0
	PUSHL	R0
	CALLS	#3,G^LIB$LOOKUP_KEY
	BLBC	R0,MATCHRET
	BISL2	KEYVALUE,NODEMASK

MATCHRET:
	RET

	.END