.TITLE	RSETUP - REPORT RSXNET SETUP
	.IDENT	/02.0/
	.ENABL	LC
;+
;
;			  Free software BY
;		Project Software & Development, Inc.
;
; This  software  is  furnished  for  free and may be used and copied as
; desired.  This software or any other copies thereof may be provided or
; otherwise  made  available  to  any  other  person.  No  title  to and
; ownership of the software is hereby transferred or allowed. 
;
; The  information  in this software is subject to change without notice
; and  should  not  be  construed  as  a commitment  by PROJECT SOFTWARE
; AND DEVELOPMENT, INC.
;
; PROJECT SOFTWARE assumes no responsibility for the use or  reliability  
; of this software on any equipment whatsoever.
;
;	Project Software & Development, Inc.
;	14 Story St.
;	Cambridge, Ma. 02138
;	617-661-1444
;
;
; Title:	RSETUP
; Author:	Robin Miller
; Date:		April 21, 1982
;
; Description:
;	   
;	This module reports the current RSXNET settings.
;
; Modification History:
;
;-
	.ENABL	AMA
	.NLIST	BEX


; Local equates:

	LF	=	10.	; LINE FEED
	CR	=	13.	; CARRIAGE RETURN

; Messages:

STATM:	.ASCII	<CR><LF>
	.ASCII	"RSXNET Status Report:"<CR><LF>

LOGM:	.ASCIZ	<CR><LF>"Log file name:	"

LOCM:	.ASCIZ	"Local output:	"
LOCEM:	.ASCIZ	"Enabled"
LOCDM:	.ASCIZ	"Disabled"

PORTM:	.ASCIZ	"Remote port:	"

INTM:	.ASCIZ	<CR><LF>"Interrupt:	"

SYSM:	.ASCIZ	<CR><LF>"System type:	"

BAUDM:	.ASCIZ	<CR><LF>"Baud rate:	"

MAXM:	.ASCII	<CR><LF>"Debug mode:	Enabled"
	.ASCIZ	<CR><LF>"Maximum B.C.:	"

	.EVEN

;+
;
; RSETUP - Report RSXNET setup.
;
;-
RSETUP::
	CALL	$SAVAL
	MOV	#LBUFF,R0		; PUT STATUS REPORT HERE

;	Heading and logfile name (if any).

	MOV	#STATM,R1		; HEADING AND LOG FILE MSG
	CALL	MOVE			; MOVE EM
	MOV	#LOGNAM,R1		; ADDRESS OF LOG FILE NAME
	TSTB	(R1)			; IS THERE A FILE NAME ?
	BNE	10$			; IF NE, YES
	MOV	#CRLF,R1		; NO, SO MOVE IN CR/LF
10$:	CALL	MOVE			; MOVE IN LOG FILE NAME

;	Local output to logfile.

	TSTB	LOGNAM			; IS THERE A LOG FILE NAME ?
	BEQ	15$			; IF EQ, NO
	MOV	#LOCM,R1		; LOCAL OUTPUT MESSAGE
	CALL	MOVE			; MOVE IT
	MOV	#LOCEM,R1		; PRESUME ITS ENABLED
	TST	LOCFLG			; IS IT REALLY ENABLED ?
	BNE	17$			; IF NE, YES
	MOV	#LOCDM,R1		; NOPE, ITS DISABLED
17$:	CALL	MOVE			; MOVE IT
	MOV	#CRLF,R1		; SET FOR SINGLE SPACE
	CALL	MOVE			; MOVE IT

;	Remote port being used.

15$:	MOV	#PORTM,R1		; ADDRESS OF PORT MSG
	CALL	MOVE			; MOVE IT
	MOV	#TTBUF,R1		; ADDRESS OF REMOTE PORT
	CALL	MOVE			; MOVE IT

;	Interrupt character being used.

	MOV	#INTM,R1		; ADDRESS OF INTERRUPT MSG
	CALL	MOVE			; MOVE IT
	MOVB	INTRPT,R1		; COPY THE INTERRUPT CHARACTER
	MOVB	R1,(R0)+		; COPY IT TO OUTPUT BUFFER
	CMPB	R1,#37			; IS IT A CONTROL CHARACTER ?
	BHI	20$			; IF HI, NO
	MOVB	#'^,-1(R0)		; PRINT CONTROL AS ^<CHAR>
	ADD	#100,R1			; MAKE CONTROL PRINTABLE
	MOVB	R1,(R0)+		; AND STORE IN OUTPUT BUFFER

;	System type of the remote.

20$:	MOV	#SYSM,R1		; ADDRESS OF SYSTEM MESSAGE
	CALL	MOVE			; MOVE IT
	MOV	SYSENT,R1		; POINTER TO THE SYSTEM TYPE
	CALL	MOVE			; MOVE IT

;	Baud rate of the remote port.

	MOV	#BAUDM,R1		; ADDRESS OF BAUD RATE MESSAGE
	CALL	MOVE			; MOVE IT
	MOV	SPDENT,R1		; POINTER TO THE BAUD RATE
	CALL	MOVE			; MOVE IT

;	Maximum byte count of an interactive read.

	TST	DEBFLG			; DEBUG OUTPUT TURNED ON ?
	BEQ	30$			; IF EQ, NO
	MOV	#MAXM,R1		; MAXIMUM BYTE COUNT MESSAGE ?
	CALL	MOVE			; MOVE IT
	MOV	MAXBC,R1		; COPY THE MAXIMUM BYTE COUNT
	CLR	R2			; SET FOR ZERO SUPPRESSION
	CALL	$CBDMG			; CONVERT BINARY TO DECIMAL

30$:	MOV	#CRLF,R1		; PUT IN SINGLE SPACING
	CALL	MOVE			; AND MOVE IT
	MOV	#LBUFF,R4		; ADDRESS OF OUTPUT BUFFER
	CALL	WRITE			; WRITE IT
	RETURN

	.END