.TITLE	STARTUP - RSXNET STARTUP MODULE
	.IDENT	/3.6/
	.ENABL	LC
;+
;
;			  Free software BY
;		Project Software & Development, Inc.
;
; This software is furnished for free and may be used and  copied as
; desired. This software or  any  other copies  thereof may be provided
; or otherwise made available to any other person.  No title to and
; ownership of  the  software  is  hereby transferred or allowed. 
;
; The information in this software is subject to change  without  notice
; and  should  not  be  construed  as  a commitment by PROJECT SOFTWARE
; AND DEVELOPMENT, INC.
;
; PROJECT SOFTWARE assumes no responsibility for the use or  reliability  
; of this software on any equipment whatsoever.
;
;	Project Software & Development, Inc.
;	14 Story St.
;	Cambridge, Ma. 02138
;	617-661-1444
;
;
; Title:	STARTUP
; Author:	Gary Larsen & Robin Miller
; Date:		February 18, 1982
;
; Description:
;	   
;	This module contains a list of user prompt messages along with
; help for the setup of asynchronous communication lines between systems.
;
; Modification History:
;
;-
	.ENABL	AMA

	.MCALL	ALUN$S, EXIT$S, GLUN$S, QIOW$S, WTSE$S


; Local Equates.

	BELL	=	7	; BELL
	LF	=	10.	; LINE FEED
	CR	=	13.	; CARRIAGE RETURN

	.NLIST	BEX

; ASCII Messages.

HELPQ:	.ASCIZ	%Do you want help information displayed (No): %

HELPH:	.ASCIZ	%INTRODUCTION%

LOGFQ:	.ASCIZ	%Write the output from the remote to a logfile (No): %

LOGFH:	.ASCIZ	%LOG_FILE%

INIDON:	.ASCIZ	%*** Initialization file complete. ***%<BELL><CR><LF>

DIALM::	.ASCII	<CR><LF>
	.ASCII	%*** If using a dialup modem, call the remote system now. ***%
	.ASCII	<CR><LF>
	.ASCIZ	%*** Once you are connected type RETURN to continue. ***%

	.EVEN
	.LIST	BEX

	.SBTTL	STARTUP - ASSIGN THE LUN AND SET UP PARAMETERS
;
; THE USER IS PROMPTED FOR THE FOLLOWING PARAMETERS
;
;	DO THEY NEED HELP ?
;	DO THEY WISH TO MAKE A LOGFILE OF THEIR SESSION ?
;	THE PORT THROUGH WHICH TO COMMUNICATE
;	THE TYPE OF SYSTEM THEY ARE COMMUNICATING WITH
;	THE BAUD RATE AT WHICH THEY WILL COMMUNICATE
;
; THE USER MAY ACCEPT THE DEFAULTS WHICH ARE IN PARENTHESIS , GET HELP
; ON THAT QUESTION BY TYPING AN ESCAPE , OR SUPPLY HIS OWN PARAMETER.
;
	.ENABL	LSB
STARTUP::
	MOV	#HDNG,R4		; ADDRESS OF HEADER
	CALL	WRITE			; AND WRITE IT

;	Check for an RSXNET.INI file

	CALL	INIFIL			; IS THERE AN INI FILE ?

;	Ask them if they need help 

10$:	TST	INIFLG			; IS THE INI FILE OPEN
	BNE	20$			; IF NE, YES
	MOV	#INCMD,R1		; ADDRESS OF USER INPUT BUFFER
	MOV	#HELPQ,R2		; ADDRESS OF HELP QUESTION
	MOV	#HELPH,HLPADR		; ADDRESS OF HELP MESSAGE
	CALL	PROMPT			; AND ASK THEM
	CMPB	#'Y,INCMD		; DO THEY NEED HELP
	BNE	20$			; IF NE, NO (CONTINUE ...)
	CALL	GETHLP			; GO TYPE SOME HELP
	
;	Do they want to output session to a logfile ?

20$:	CALL	GETINI			; GET COMMAND LINE IF INI FILE OPEN
	BCC	40$			; IF CC, OK
30$:	CALL	CLOINI			; CLOSE THE INI FILE IF OPEN
	MOV	#INCMD,R1		; ADDRESS OF USER INPUT BUFFER
	MOV	#LOGFQ,R2		; ADDRESS OF LOGFILE QUESTION
	MOV	#LOGFH,HLPADR		; ADDRESS OF HELP MESSAGE
	CALL	PROMPT			; AND ASK THEM
	TST	BCKFLG			; DO THEY WANT TO BACKUP
	BNE	10$			; IF NE, YES
40$:	CMPB	#'Y,INCMD		; DO THEY WANT A LOGFILE ?
	BNE	50$			; IF NE, NO (CONTINUE)
	CALL	LOGFIL			; AND OPEN IT
	TST	BCKFLG			; USER WANT TO BACKUP ?
	BNE	30$			; IF NE, YES

;	What is the remote port ?

50$:	CALL	GRPORT			; GET THE REMOTE PORT
	TST	BCKFLG			; NEED TO BACKUP ?
	BNE	30$			; IF NE, YES

;	Get the interrupt character

60$:	CALL	INTCHR			; GET THE INTERRUPT CHARACTER
	TST	BCKFLG			; NEED TO BACKUP ?
	BNE	50$			; IF NE, YES

;	Get the system type

70$:	CALL	SYSTEM			; GET THE SYSTEM TYPE
	TST	BCKFLG			; NEED TO BACKUP ?
	BNE	60$			; IF NE, YES

;	Get the baud rate

80$:	CALL	SPEED			; SET THE BAUD RATE
	TST	BCKFLG			; NEED TO BACKUP ?
	BNE	60$			; IF NE, YES

;	Close the initialization file if still open.

90$:	TST	INIFLG			; IS THE .INI FILE OPEN ?
	BEQ	100$			; IF EQ, NO
	CALL	CLOINI			; CLOSE THE .INI FILE
	CALL	RSETUP			; REPORT RSXNET SETUP
	CALL	BLANK			; WRITE A BLANK LINE
	MOV	#INIDON,R4		; TELL THE USER IT'S DONE
	CALL	WRITE			; AND GO DO IT

100$:	CMPB	#1,SMODM+1		; IS THIS A POSSIBLE DIALUP ?
	BNE	110$			; IF NE, NO
MODEM::	MOV	#DIALM,R4		; TELL USER TO DIALUP REMOTE
	CALL	WRITE			; WRITE IT
105$:	QIOW$S	#IO.RAL,#LOCAL,#LOCAL,,#LIOSB,,<#INCMD,#1> ; GET THE REPLY
	CALL	CHKLIO			; CHECK FOR ERRORS
	CMPB	#CR,INCMD		; CONTINUE ?
	BNE	105$			; IF NE, NO
	DIR$	#SETREM			; RESET REMOTE CHARACTERISTICS

110$:	RETURN
	.DSABL	LSB

	.END