;_Header
;*******************************************************************
;    NOVA CONTROL SYSTEM  ---  Lawrence Livermore Laboratory
;
;    Copyright 1984 by The Regents of the University of California
;*******************************************************************
;
;_Module_Name:  PRXMACLIB		_File:  [VCDEV.PRXRTS]PRXMACLIB.MAC
;
;_Description:
;	Praxis macro library for Stand-alone LSI-11
;_Call:
;_Remarks:
;_Identifier: { none }
;*******************************************************************
;_Author:  T. A. SHERMAN		_Creation_Date:  13-APR-1984
;_Revisions:
;.IDENT	1.000  13-APR-1984  TAS	Initial Key-in.
;*******************************************************************
;_End
	.TITLE	PRXMLB

	.MACRO	PRXMLB
	.MCALL	EXCEPTION
	.MCALL	RAISE
	.MCALL	PRINT
	.MCALL	INITTBL
	.MCALL	TERMTBL
	.ENDM

;	.MACRO	MODULE	NAME
;	.TITLE	NAME
;	.ENDM

;	.MACRO	DECLARE
;	.PSECT	$PDATA,REL,CON,LCL,D,RO
;	.ENDM

	.MACRO	EXCEPTION	ID
	.PSECT	$PDATA,REL,CON,LCL,D,RO
	.EVEN
ID::
	.NCHR	N,<ID>
	.WORD	N
	.ASCII	/ID/
	.EVEN
	.WORD	0
	.PSECT	$CODE1,REL,CON,LCL,I,RO
	.ENDM

	.MACRO	RAISE	ID
	MOV	#ID,-(SP)
	JSR	PC,PRX$RAISE
;	TST	(SP)+
	.ENDM

	.MACRO	PRINT	TEXT,VAL,?LABEL
	.ENABL	LSB
	.PSECT	$PDATA,REL,CON,LCL,D,RO
	.EVEN
LABEL:
	.NCHR	N,<TEXT>
	.WORD	N+2
	.ASCII	<15><12>/TEXT/
	.EVEN
	.WORD	0
	.PSECT	$CODE1
	MOV	#LABEL,-(SP)
	JSR	PC,PUTSTR
	.IF	B,VAL
	TST	(SP)+
	.IFF
	CLR	(SP)
	CLR	-(SP)
	MOV	VAL,-(SP)
	JSR	PC,PUT$OCTAL
	ADD	#6,SP
	.ENDC
	.DSABL	LSB
	.ENDM

	.MACRO	INITTBL	ARG
	.PSECT	$INIT1,REL,CON,LCL,D,RO
	.WORD	ARG
	.ENDM

	.MACRO	TERMTBL	ARG
	.PSECT	$TERM1
	.WORD	ARG
	.ENDM

	.MACRO	PWFTBL	ARG
	.PSECT	$PWF1
	.WORD	ARG
	.ENDM

	.END