!+
!	LIST_COMMANDS.TPU	 - Routine to list all EVE (or EVEplus)
!				   commands (sort alphabetically, perhaps)
!-

procedure eve_list_commands

local	the_names,
	column_width,
	total_width,
	how_many_columns,
	temp;

    eve_mark("eveplus_saved_buffer");
    the_names := expand_name("eve_", procedures) + " ";
    position(eve$choice_buffer);
    erase(eve$choice_buffer);
    message("Building command list");
    
    loop
	exitif (the_names = eve$x_null);
	temp := index (the_names, " ");
        if (temp = 0) then
            message("Can't find space");
            return;
        endif;
	copy_text (substr (the_names, 1, temp-1));
        the_names := substr(the_names, temp+1, length(the_names));
        split_line;
	erase_line;
    endloop;
    
    position(beginning_of(current_buffer));
    loop
        temp := eveplus_search_quietly(line_begin & "EVE_", FORWARD);
        exitif (temp = 0);
        position(temp);
        erase(temp);
    endloop;

    position(beginning_of(current_buffer));
    loop
        exitif (eveplus_replace(" EVE_", " ") = 0);
    endloop;

    position(beginning_of(current_buffer));
    loop
        temp := eveplus_search_quietly(" ", FORWARD);
        exitif (temp = 0);
        position(temp);
        erase(temp);
        split_line;
    endloop;

    position(beginning_of(current_buffer));
    loop
        exitif (eveplus_replace("_", " ") = 0);
    endloop;

    if (eveplus_defined_procedure("eveplus_sort")) then
        message("Sorting command list");
        execute('eveplus_sort ( current_buffer , "" );');
    endif;
    eve$format_choices;

    set (status_line, info_window, reverse, " Eve commands -- DO will remove this list");
    position(show_buffer);
    erase(show_buffer);
    copy_text(eve$choice_buffer);
    position(beginning_of(current_buffer));
    set(screen_update, off);
    eve_go_to("eveplus_saved_buffer");
    set(screen_update, on);
    map (info_window, show_buffer);
    message(" ");

endprocedure