; TTYINI - SYSTEM DEPENDENT (RSX VERSION) TERMINAL INITS
; USES LUN 5
	.TITLE	TTYINI
	.GLOBL	TTYINI,TTYDEI
	.MCALL QIOW$S,QIOW$,DIR$
;SET TERMINAL UP NOWRAP, ESCSEQ,TYPEAHEAD
;ATTACH TERMINAL
	.PSECT	TTYII,RW,D
DET:	QIOW$	IO.DET,5,5,,IOXX
DET2:	QIOW$	IO.DET,6,5,,IOXX
ATT:	QIOW$	IO.ATT!TF.ESQ,5,5,,IOXX
SET:	QIOW$	SF.SMC,5,5,,IOXX,,<SBF,SBFSZ>
ATT2:	QIOW$	IO.ATT!TF.ESQ,6,5,,IOXX
SET2:	QIOW$	SF.SMC,6,5,,IOXX,,<SBF,SBFSZ>
IOXX:	.WORD	0,0	;DUMMY I/O STAT BLK
	.IF	NDF,$VT52
;SETUP AUX KEYPAD
	.EVEN
AKPBF:	.BYTE	33,75
	.EVEN
AKP:	QIOW$	IO.WLB,6,5,,IOXX,,<AKPBF,2>
	.ENDC
SBF:	.BYTE	TC.ACR,0	;NOWRAP
	.BYTE	TC.CTS,0	;CANCEL CTRL S
	.BYTE	TC.ESQ,1	;ESCSEQ
	.BYTE	TC.RAT,1	;TYPEAHEAD (NOTE REQUIRES FULL DUP DRIVER)
	.BYTE	TC.FDX,1	;SOFTWARE FULL DUPLEX
SBFSZ=.-SBF
	.PSECT	TTYIII,I
TTYINI::
	DIR$	#ATT	;ATTACH TERMINAL
	DIR$	#SET	;SET CHARACTERISTICS
	DIR$	#ATT2
	DIR$	#SET2
	.IF NDF,$VT52
	DIR$	#AKP	;SET AUX KEYPAD MODE
; IDEA IS TO ALLOW NUMBERS ON AUX KEYPAD TO COME IN AS DIGITS
	.ENDC
	RTS	PC
TTYDEI:	DIR$	#DET	;DETACH TERMINAL
	DIR$	#DET2	;ON LUNS 5 AND 6 BOTH
	RTS	PC
	.END