DELETE X_Y_CON;
REDEFINE PLOT X_Y_CON
!
!This routine is based upon DEC code for the plots X_Y and CONNECT.  It
!plots data using connected lines rather than plotting lines between
!data marker symbols as the combination of the two DEC supplied plots does.
!
!	Donald E. Stern, Jr.  -  May 17, 1984
!
DECLARE X_AXIS, Y_AXIS, X_LENGTH, Y_LENGTH, X_MAX, X_MIN, Y_MIN, Y_MAX
DECLARE X_POS, Y_POS, I
DECLARE VECTOR XS, YS
ENTRY 0 (X_LABEL : STRING, Y_LABEL : STRING)
    BEGIN
	PLOT HOUSEKEEP 0
	SET_SEGMENT 1
	X_AXIS = 100
	Y_AXIS = 360
	X_LENGTH = 600
	Y_LENGTH = 350
	PLOT LABEL 0 (X_AXIS, Y_AXIS, X_LENGTH, Y_LENGTH, X_LABEL, Y_LABEL)
    END
ENTRY 1 (X : REAL : "horizontal coordinate", Y : REAL : "vertical coordinate")
	BEGIN
	XS (SIZE (XS) + 1 ) = X
	YS (SIZE (YS) + 1 ) = Y
    END
! Print scatter plot
ENTRY 2
    BEGIN
	X_MIN = MIN (XS)
	X_MAX = MAX (XS)
	Y_MAX = MAX (YS)
	Y_MIN = MIN (YS)
	IF Y_MIN > 0
	    THEN Y_MIN = 0
	PLOT LABEL 2 (X_MIN, X_MAX, XS)
	PLOT LABEL 3 (Y_MIN, Y_MAX)
	PLOT LABEL 8 (YS)
	PLOT LABEL 9(XS,YS,Y_AXIS)
	SORT (XS,YS)
	PRINT 'P', LXY (XS(1), YS(1)), 'V'
	INCR I OVER XS
	    PRINT LXY(XS(I), YS(I))
	OUTPUT_SEGMENT 1
	PLOT HOUSEKEEP 2
    END
END_PLOT