!       DISPLAY_CHARACTER.TPU
!-
! This procedure writes a one line message describing the current character
! in terms of Octal, Decimal, Hexadecimal and (sometimes) '^' notation.
!	--from DECUS submission by T. W. WILLIAMS

PROCEDURE tww_eve_display_character

  LOCAL i,cc,reps,rep;
  REPS := "0<NUL>1<SOH>2<STX>3<ETX>4<EOT>5<ENQ>6<ACK>7<BEL>"
        + "8<BS>9<HT>10<LF>11<VT>12<FF>13<CR>14<SO>15<SI>"
        + "16<DLE>17<DC1>18<DC2>19<DC3>20<DC4>21<NAK>22<SYN>23<ETB>"
        + "24<CAN>25<EM>26<SUB>27<ESC>28<FS>29<GS>30<RS>31<US>"
        + "32<SP>127<DEL>132<IND>133<NEL>134<SSA>135<ESA>136<HTS>"
        + "137<HTJ>138<VTS>139<PLD>140<PLU>141<RI>142<SS2>143<SS3>"
        + "144<DCS>145<PU1>146<PU2>147<STS>148<CCH>149<MW>150<SPA>"
        + "151<EPA>155<CSI>156<ST>157<OSC>158<PM>159<APC>";

  ! Handle end-of-buffer condition
  IF MARK( NONE ) = END_OF( CURRENT_BUFFER ) THEN
    MESSAGE( 'At end of buffer, no current character.' );
    RETURN;
  ENDIF;

  ! Convert the character to an integer the hard way (no builtin yet)
  i := 0; LOOP;
    EXITIF i > 255;
    EXITIF CURRENT_CHARACTER = ASCII(i);
    i := i + 1;
  ENDLOOP;

  IF i > 255 THEN i := 0; ENDIF; ! On overflow, reset to NULL

  ! Provide ^ notation for ASCII control characters
  IF i < 32
    THEN cc := ', ^' + ASCII(i+64);
    ELSE cc := '';
  ENDIF;
  ! Provide mnemonic representation, too.
  IF (  I <= 32) OR  ( I = 127)  OR
     (( I > 131) AND ( I < 152)) OR
     (( I > 154) AND ( I < 160))
  THEN
     REP := SUBSTR( REPS,
                    INDEX( REPS, STR( I)) + LENGTH( STR( I)),
                    5);
     IF SUBSTR( REP, 5, 1) <> ">"
     THEN
        REP := SUBSTR( REP, 1, 4);
     ENDIF;
  ELSE
     REP := CURRENT_CHARACTER;
  ENDIF;

  ! Format and output the results
  MESSAGE( FAO( "Current Character is '!AS', Decimal=!UB, " +
                "Hex=!-!XB, Octal=!-!OB!AS", REP, i, cc ) );

ENDPROCEDURE; ! eve_display_character
!+