PROCEDURE	cjc_get_filelist

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!  TPU procedure to prompt for a file-spec, then produce a list of files
!  fitting that spec, in the DCL buffer (erasing version-numbers as it
!  works). Invokes DIR/NOHEADER/NOTRAILER to do this
!  Useful (together with the procedures in FILLS.SRC) to aid in building
!  COM files via cut-and-paste
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

LOCAL	dir_spec_str ,
	semi_loc ,
	end_loc  ;

eve$prompt_string
	(
	'' ,
	dir_spec_str ,
	"Enter file-spec:  " ,
	"No file-spec entered; listing all files in current directory."
	) ;

eve_dcl ( "dir/noheader/notrailer/versions=1 " + dir_spec_str ) ;

eve_other_window ;

position ( search ( "dir" , REVERSE , EXACT ) ) ;

loop
	semi_loc  :=  search ( ';' , FORWARD ) ;
	exitif ( semi_loc = 0 ) ;
	position ( semi_loc ) ;
	position ( search ( LINE_END , FORWARD ) ) ;
	move_horizontal ( -1 ) ;
	end_loc  :=  mark ( NONE ) ;
	erase ( create_range (
		beginning_of ( semi_loc ) , end_loc , NONE ) ) ;
endloop ;

return ;

ENDPROCEDURE ;