!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!   Procedure to initiate two windows with the current cursor-position   !
!   as the boundary between them:
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


PROCEDURE   cjc_set_window_top_here

LOCAL	this_position ,
        this_row      ,
        dtop1         ,
        dbot1      ,
        dtop2         ,
        dbot2      ;


    eve$check_bad_window ;

    this_position  :=  mark ( NONE ) ;
    this_row       :=  get_info ( current_window , "current_row" ) ;
    this_buffer    :=  current_buffer ;

    if  eve$x_number_of_windows = 1   then

        unmap ( eve$main_window ) ;

        map   ( eve$top_window    , this_buffer ) ;
        eve$set_status_line ( eve$top_window    ) ;

        map   ( eve$bottom_window , this_buffer ) ;
        eve$set_status_line ( eve$bottom_window ) ;

        eve$x_number_of_windows  :=  2 ;
        eve$x_this_window  :=  eve$bottom_window ;

    endif ;

    dtop1  :=  0 ;
    dbot1  :=  this_row
                 -  get_info ( eve$top_window , "visible_bottom" )
                 -  1 ;
    dtop2  :=  get_info ( eve$bottom_window , "visible_top" )
                 -  this_row
                 +  1 ;
    dbot2  :=  0 ;


    adjust_window ( eve$top_window    , dtop1 , dbot1 ) ;
    adjust_window ( eve$bottom_window , dtop2 , dbot2 ) ;

    eve$top_window_length     :=  eve$top_window_length     +  dbot1 ;
    eve$bottom_window_length  :=  eve$bottom_window_length  -  dtop2 ;

eve$position_in_middle ( this_position ) ;


ENDPROCEDURE ;