PROCEDURE	cjc_toggle_width

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!  TPU procedure to toggle back and forth between the following widths
!  and margins:
!	width 7 -- 72  , margins  7 -- 72
!	width 1 -- 80  , margins  1 -- 88
!	width 1 -- 132 , margins  1 -- 132
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

LOCAL	current_width ,
        last_window   ,
        loop_window   ,
        loop_buffer   ;

current_width  :=  get_info ( current_window , "width" ) ;
last_window    :=  get_info ( WINDOWS , EVE$KT_LAST  ) ;
loop_window    :=  get_info ( WINDOWS , EVE$KT_FIRST ) ;

loop
        loop_buffer  :=  get_info ( loop_window , "buffer" ) ;
	if      ( current_width = 72 )  then
	    set ( WIDTH , loop_window , 80 ) ;
	    if ( loop_buffer <> 0 )  then
              set ( MARGINS, loop_buffer , 1 , 88 ) ;
            endif ;
	else if ( current_width = 80 )  then
	    set ( WIDTH , loop_window , 132 ) ;
	    if ( loop_buffer <> 0 )  then
	      set ( MARGINS, loop_buffer , 1 , 132 ) ;
            endif ;
        else if ( current_width = 132 )  then
	    set ( WIDTH , loop_window , 80 ) ;	! resets character-size
	    set ( WIDTH , loop_window , 72 ) ;
	    if ( loop_buffer <> 0 )  then
              set ( MARGINS, loop_buffer , 7 , 72 ) ;
            endif ;
	endif ; endif ; endif ;

        exitif ( loop_window  =  last_window ) ;
        loop_window  :=  get_info ( windows , "next" ) ;

endloop ;

if      ( current_width = 72 )  then
    message ( "Reset width and margins--WIDTH:  80, MARGINS 1 - 88" ) ;
else if ( current_width = 80 )  then
    message ( "Reset width and margins--WIDTH:  132, MARGINS 1 - 132" ) ;
else if ( current_width = 132 )  then
    message ( "Reset width and margins--WIDTH:  72, MARGINS 7 - 72" ) ;
endif ; endif ; endif ;

if ( eve$x_number_of_windows = 2 )  then
        update ( eve$top_window    ) ;
        update ( eve$bottom_window ) ;
else
        update ( eve$main_window    ) ;
endif ;

return ;

ENDPROCEDURE ;