.title  /Operator Message/
;
                $opcdef
                $opcmsg
;
                .psect  opr_data, noexe, pic, noshr
;
opmsg:          .byte   OPC$_RQ_RQST            ; We want to request to the operator
                .byte   OPC$M_NM_CENTRL         ; Send it to the central operator
                .word   0                       ; Just null space
                .long   0                       ; Just null space
text:           .blkb   80                      ; Place to put the message string
OPMSGLEN = . - opmsg                            ; Length of the operator message
;
msgdsc:         .long   OPMSGLEN                ; Length of string to pass to sys$sndopr
                .long   opmsg                   ; Where the string is
;
;
;
;*******************************************************************************
;* Oprmsg                                                                      *
;*      This procedure takes a string of up to 72 characters and sends it to   *
;* the operators console.                                                      *
;*******************************************************************************
;
                .psect  opr_code, exe, pic, shr, nowrt
;
                .entry  oprmsg, ^m<>
;
                movl    4(ap), r0               ; Save string to send
;
                movc5   (r0), @4(r0), #32, #80, text ; Move the user string in
                $sndopr_s msgdsc                ; Send request
;
                ret                             ; End of oprmsg
;
                .end