!D E C U S - I N T E R O F F I C E   M E M O R A N D U M
!
!Date:       20-Dec-1990 08:28pm EST
!From:       Winston Tellis 
!Dept:       SIG STEERING COMM.:
!Tel No:     203-254-4000
!
!TO:  Bart Z. Lederman                     ( LEDERMAN )
!
!
!Subject:    accent prob - 2

! CS CODE_SEGS

SEGMENT CONCAT_NAME
! $ARG_0 is seniority
! $ARG_1 is last name
! $ARG_2 is first name
! $ARG_3 is middle initial
! $ARG_4 is title

    ' ' TO NAME:D    !init to blank each time

    IF:10 $ARG_0 # ' '    !if seniority exists
      $ARG_0 TO NAME:D    !push it onto the name string
      IF:20 $ARG_0 NOT BEGINS WITH 'I'   !if seniority is not II, III
        ', ' + NAME:D + '.' TO NAME:D        !then make it ", JR.", for example
      ELSE:20
        ' ' + NAME:D TO NAME:D    !otherwise, make it " III", for example
      CONTINUE:20
    CONTINUE:10

    @RTRIM $ARG_1 + NAME:D TO NAME:D   !push on the last name

    IF:10 $ARG_3 # ' '   !if middle initial exists
      $ARG_3 + '. ' + NAME:D TO NAME:D   !concat w/period and push it on
    CONTINUE:10

    @RTRIM $ARG_2 + ' ' + NAME:D TO NAME:D   !push on the first name

    ' ' TO @STRING   !init string to blanks
    IF:10 $ARG_4 # ' '   !if title exists
      $ARG_4 TO @STRING  !then copy to string
      IF:20 $ARG_4 # 'MISS' AND $ARG_4 # 'SIR' !if title not Miss or Sir
        @RTRIM @STRING + '.' TO @STRING   !then tack a period after it
      CONTINUE:20
      IF:20 $ARG_4 # 'ESQ'  !if the title is not Esquire
        @RTRIM @STRING + ' ' + NAME:D TO NAME:D   !push on title
      ELSE:20   !else title is Esquire
        @RTRIM NAME:D + ', ' + @STRING TO NAME:D  !Esquire is at end of name
      CONTINUE:20
    CONTINUE:10


SEGMENT PROCESS_DETAIL_REC

  !$ARG_0 identifies type of processing required (i.e. "MODIFY", "ADD")
  START:100
!    TYPE '      Date:  ', NOCR
	SCREEN PUT_CHARS IW:D,'Date:  ',4,4,@SCN_NOERASE,@SCN_NORMAL
    IF:110 $ARG_0 = 'MODIFY'
!      TYPE DATED:DET,5S, NOCR
	SCREEN PUT_CHARS IW:D, @DATSTR DATED:DET,4,18,@SCN_NOERASE,@SCN_NORMAL
    CONTINUE:110 
    ' ' TO @STRING(20)
!    ACCEPT @STRING(20)
	@SCN_READ_CHAR (IW:D, 4, 30, 8, @SCN_NORMAL) TO @STRING(20)
    IF:110 @STRING(20) = ' ' AND $ARG_0 = 'MODIFY'
      @DATSTR DATED:DET TO @STRING(20)
    ORIF:110 @STRING(20) # ' '
      IF:120 @STRING(20) NOT CALENDRICAL
        ' ' TO @STRING(20)
      CONTINUE:120
    CONTINUE:110
  LEAVE:100 IF @STRING(20) # ' '
  REPEAT:100

  START:100
!    TYPE '   Donation:  ', NOCR
	SCREEN PUT_CHARS IW:D,'Donation:  ',5,4,@SCN_NOERASE,@SCN_NORMAL
    IF:110 $ARG_0 = 'MODIFY'
!      TYPE AMOUNT:DET,5S, NOCR
	SCREEN PUT_CHARS IW:D,@STR (AMOUNT:DET, "6$.$$"),5,18,@SCN_NOERASE,@SCN_NORMAL
    CONTINUE:110;  '' TO @STRING(10)
!    ACCEPT @STRING(10)
	@SCN_READ_CHAR (IW:D, 5, 30, 8, @SCN_NORMAL) TO @STRING(10)
    IF:110 @STRING(10) = '' AND $ARG_0 = 'MODIFY'
      AMOUNT:DET TO @NUMBER(10)
    ORIF:110 @STRING(10) = '' AND $ARG_0 = 'ADD'
      0.0 TO @NUMBER(10)
    ORIF:110 @STRING(10) # ''
      @NVAL @STRING(10) TO @NUMBER(10)
    CONTINUE:110
  LEAVE:100 IF @NUMBER(10) >= 0.0
  REPEAT:100

  START:100
     SCREEN PUT_CHARS IW:D,'Key H for list of fund codes', 9, 4, @SCN_ERASE, @SCN_BOLD
!    TYPE '  Fund Code:  ', NOCR
	SCREEN PUT_CHARS IW:D,'Fund Code:  ',6,4,@SCN_NOERASE,@SCN_NORMAL
    IF:110 $ARG_0 = 'MODIFY'
!      TYPE FCODE:DET,5S, NOCR
	SCREEN PUT_CHARS IW:D,@STR FCODE:DET,6,18,@SCN_NOERASE,@SCN_NORMAL
    CONTINUE:110;  '' TO @STRING(10)
!    ACCEPT @STRING(10)
      START:110
        @SCN_READ_CHAR (IW:D, 6, 30, 1, @SCN_NORMAL) TO @STRING(10)
      LEAVE:110 UNLESS @LEFT (@STRING(10), 1) = 'H'
        PERFORM DISPLAY_FUNDS
      REPEAT:110
    IF:110 @STRING(10) = '' AND $ARG_0 = 'MODIFY'
      FCODE:DET TO @INTEGER(11)
    ORIF:110 @STRING(10) = '' AND $ARG_0 = 'ADD'
      0 TO @INTEGER(11)
    ORIF:110 @STRING(10) # ''
      @IVAL @STRING(10) TO @INTEGER(11)
    CONTINUE:110
  LEAVE:100 IF @INTEGER(11) BETWEEN 0 AND 9
  REPEAT:100
  SCREEN ERASE_LINE IW:D, 9, 4
      
  IF:100 $ARG_0 = 'ADD'
    @CAL @STRING(20) TO DATED:DET:R
    @NUMBER(10) TO AMOUNT:DET:R
    @INTEGER(11) TO FCODE:DET:R
  ORIF:100 $ARG_0 = 'MODIFY'
    @CAL @STRING(20) TO DATED:DET
    @NUMBER(10) TO AMOUNT:DET
    @INTEGER(11) TO FCODE:DET
  CONTINUE:100