;--------------------------------------------------------------------------
;System         : Decus 4GL comparison
;Program        : MASTER Editor
;Author         : Ron Owen
;Date           : 21-OCT-1990
;--------------------------------------------------------------------------
;				REVISION HISTORY
;
;	1(0)	- Release New
;
;
;
;
;
;--------------------------------------------------------------------------
SCREEN MASTER FROM 1,1 TO 8,80&
ACTIONBAR ON LINE 1 &
NOMODE NOACTION &
FIELDMARK &
HELP POPUP FROM 15,5 TO 22,65 &
MESSAGE POPUP information,warning,error,severe FROM 15,15 TO 22,65
ACTIONMENU LABEL "  FILE  "
    MENUITEM LABEL "NEW " 		ACTION ENTRY
    MENUITEM LABEL "FIND " 		ACTION FIND
    MENUITEM LABEL "FIND/NEXT" 		ACTION NEXT DATA
    MENUITEM LABEL "COMMIT DATA" 	ACTION UPDATE STAY
    MENUITEM LABEL "DELETE " 	 	ACTION DELETE
    MENUITEM LABEL "PRINT SCREEN"	ACTION LIST
    MENUITEM LABEL "EXIT " 	 	ACTION RETURN
ACTIONMENU LABEL "  EDIT  "
    MENUITEM LABEL "CHANGE DATA" 	ACTION FIELDMARK
ACTIONMENU LABEL "  SPECIAL  "
    MENUITEM LABEL "VMS MAIL "	        ACTION DESIGNER MAIL
    MENUITEM LABEL "VMS PHONE "	        ACTION DESIGNER PHONE
ACTIONMENU LABEL "  HELP  " ACTION EXTENDED HELP
;
;------------------------------------------------------------------------
;
TEMP SOUNDFIELD CHAR*15
DEFINE SOUNDEX-KEY CHAR*4 = SOUNDEX(SOUNDFIELD)
;
TEMP WS-DETAIL-CNT NUM*4
TEMP WS-DONATION-TOT NUM*9
TEMP WS-APPL-ID CHAR*4
TEMP WS-APPENV  CHAR*4
;
;------------------------------------------------------------------------
;
FILE MASTER_RECORD PRIMARY
ACCESS VIA ID_NUMBER REQUEST ID_NUMBER
ACCESS VIA LAST_NAME REQUEST LAST_NAME
ACCESS VIA LAST_NAME_SKEY USING SOUNDEX-KEY REQUEST SOUNDFIELD
ACCESS VIA FIRST_NAME REQUEST FIRST_NAME
ACCESS SEQUENTIAL
DEFINE SOUNDEX-KEY2 CHAR*4 = SOUNDEX(LAST_NAME)
ITEM last_name_skey final soundex-key2
;
FILE DETAIL_RECORD DELETE OCCURS WITH MASTER_RECORD
;
;------------------------------------------------------------------------
;
DRAW FROM 2,1 TO 8,80
hilite data UNDERLINE
hilite actionbar off
hilite actionbarmark inverse
;
;------------------------------------------------------------------------
;
ALIGN (3,6,17)
SKIP TO 3
FIELD ID_NUMBER OF MASTER_RECORD REQUIRED NOCHANGE  &
     LOOKUP NOTON MASTER_RECORD
ALIGN (3,6,17) (34,37,60)
FIELD LAST_NAME OF MASTER_RECORD REQUIRED NOCHANGE
FIELD SOUNDFIELD LABEL "LAST NAME SOUND SEARCH" NOENTRY NOCHANGE
ALIGN (3,6,17) (34,37,52) (59,62,68)
FIELD FIRST_NAME OF MASTER_RECORD REQUIRED NOCHANGE
FIELD MIDDLE_INITIAL OF MASTER_RECORD
FIELD TITLE_OF_ADDRESS OF MASTER_RECORD LABEL "Title"
ALIGN (3,6,17)
FIELD SENIORITY OF MASTER_RECORD
ALIGN (3,6,17) (34,37,42) (55,58,64) (68,71,75)
FIELD ADDR OF MASTER_RECORD label "Address"
FIELD CITY OF MASTER_RECORD
FIELD STATE OF MASTER_RECORD
FIELD ZIP_CODE OF MASTER_RECORD Label "Zip"
;
PROCEDURE POSTFIND
BEGIN
    DISPLAY ID_NUMBER
    DISPLAY LAST_NAME
    DISPLAY SOUNDFIELD
    DISPLAY FIRST_NAME
    DISPLAY MIDDLE_INITIAL
    DISPLAY TITLE_OF_ADDRESS
    DISPLAY SENIORITY
    DISPLAY ADDR
    DISPLAY CITY
    DISPLAY STATE
    DISPLAY ZIP_CODE
    RUN SCREEN MASTER2 PASSING MASTER_RECORD MODE F
END
PROCEDURE ENTRY
BEGIN
    ACCEPT ID_NUMBER OF MASTER_RECORD
    ACCEPT LAST_NAME OF MASTER_RECORD
    ACCEPT FIRST_NAME OF MASTER_RECORD
    ACCEPT MIDDLE_INITIAL OF MASTER_RECORD
    ACCEPT TITLE_OF_ADDRESS OF MASTER_RECORD
    ACCEPT SENIORITY OF MASTER_RECORD
    ACCEPT ADDR OF MASTER_RECORD
    ACCEPT CITY OF MASTER_RECORD
    ACCEPT STATE OF MASTER_RECORD
    ACCEPT ZIP_CODE OF MASTER_RECORD
    RUN SCREEN MASTER2 PASSING MASTER_RECORD  MODE E
END
BUILD