$!
$   SET OUTPUT_RATE=:0:05
$   SET PROCESS /NAME="LAST LOGIN"
$   here := DSK1:[ADMINIS.LAST_LOG]
$!
$   DEFINE /USER  SYS$COMMAND  SYS$INPUT 
$!
$   SET DEFAULT SYS$SYSTEM
$!
$   RUN AUTHORIZE
LIST/BRIEF
$!
$   COPY SYSUAF.LIS 'here'SYSUAF.LIS
$   DELETE SYSUAF.LIS.0
$!
$ RETURN_BRIEF:
$!   WRITE SYS$OUTPUT " "
$   SET DEFAULT 'here'
$!
$!                  GET DIRECTORY CREATION DATES
$!
$   OPEN/READ UAF 'here'SYSUAF.LIS
$   DEFINE SYS$OUTPUT 'here'TEMP.FILE
$   READ/END=CLOSE_FILE UAF USER                   ! HEADER
$   READ/END=CLOSE_FILE UAF USER                   ! BLANK HEADER
$!
$ FILE_CREATES:
$   READ/END=CLOSE_FILE UAF USER
$   LEN = F$LENGTH(USER)
$   IF(LEN .NE. F$LOCATE("NOWHERE",USER))THEN GOTO FILE_CREATES
$!
$   IF(F$LOCATE(".",USER) .NE. LEN)THEN GOTO FILE_CREATES
$   COLON = F$LOCATE(":[",USER)
$   DSKLEN = COLON - 69
$   DISK = F$EXTRACT(69,DSKLEN,USER)
$   IF(F$EXTRACT(0,3,DISK) .EQS. "UPC")THEN GOTO FILE_CREATES
$   COLON = COLON + 2
$   USERNAME = F$EXTRACT(COLON,25,USER) - "]"
$   DIRECTORY/date 'DISK':[000000]'USERNAME'.DIR
$   GOTO FILE_CREATES
$!
$ CLOSE_FILE:
$   DEASSIGN SYS$OUTPUT
$   CLOSE UAF
$!
$ RUN_DIR_PROG:
$   RUN 'here'DIRECTRY.EXE
$!
$!                     FIND OUT LAST DATE OF LOGIN
$!
$   SET DEFAULT SYS$SYSTEM
$!
$   RUN AUTHORIZE
LIST/FULL
$!
$   COPY SYSUAF.LIS 'here'SYSUAF.LIS
$   DELETE SYSUAF.LIS.0
$!
$ RETURN_FULL:
$!   WRITE SYS$OUTPUT " "
$   SET DEFAULT 'here'
$!
$ RUN_FOR:
$   RUN 'here'LAST_LOGIN.EXE             ! COMPILED WITH  /NOOP
$!
$ MAIL_LIST:
$   MAIL /SUBJECT="LAST LOGIN" LAST.LOG @'here'SPG.DIS 
$   MAIL /SUBJECT="NO LOGIN" NEVER.LOG @'here'SPG.DIS
$!
$ CLEAN_UP:
$   DEL          'here'SYSUAF.LIS.*
$   DEL          'here'CREATE.LIS.*
$   DEL          'here'TEMP.FILE.*
$   DEL          'here'LIMIT.DAT.*
$   DEL          'here'SORT.DAT.*
$   DEL          'here'*.SRT.*
$   PURGE        'here'SYSTEM.DAT
$   PURGE        'here'SPG.DIS
$   PURGE/KEEP=2 'here'*.LOG
$!
$ EXIT:
$   EXIT