$!			MODEM.COM
$!
$!	This command file will hook up with DF-224 modem dropped off the
$! network for outbound purposes.
$!
$!	p1 : If there is a value in p1, the call will be logged to 
$!		SYS$LOGIN:DF224_MODEM.LOG
$!
$! ---------------------------------------------------------------------------
$	if p1.eqs."" then goto start_checking
$	p1 := "/log=SYS$LOGIN:DF224_MODEM.LOG"
$! ---------------------------------------------------------------------------
$!
$	set message/nofacility/noidentification/noseverity/notext
$!
$!	Checking for other outbound calls (LTA9 in use) or an inbound call
$!	(623-5803 appears in SHOW USERS).  Either way, bounce them out.
$!
$ start_checking:
$	on error then goto end
$	answer = f$getdvi("_lta9:","all")
$	if answer .eqs. "true" then goto modem_inuse
$	show user/ful/output=sys$login:show_users.out
$	search sys$login:show_users.out "5803" /output=sys$login:show_users2.out
$!$	if f$search ("sys$login:show_users2.out") .nes. "" then goto modem_inuse
$	if $status .eq. %x00000001 then goto modem_inuse 
$	delete/nolog/noconf sys$login:show_user*.out;*
$	on warning then goto modem_inuse
$	allocate lta9:
$	write sys$output ""
$	write sys$output "The MODEM is yours.  Go ahead."
$	write sys$output ""
$	assign/user sys$command sys$input
$	set host/dte lta9: 'p1'
$	write sys$output ""
$	write sys$output "We now return to your regularly scheduled program.  Thank-you."
$	write sys$output ""
$	goto end
$!
$ modem_inuse:
$	write sys$output ""
$	write sys$output "The MODEM is currently in use.  Please try again later."
$	write sys$output ""
$	inquire/nopunct answer "Hit <return> to continue."
$	delete/nolog/noconf sys$login:show_user*.out;*
$!
$ end:
$	deallocate lta9:
$	set message/facility/identification/severity/text
$	exit