;
;	procedure pour copier l'executable psicopy.exe chez vous
;	(modifier le cas échéant l'adresse DTE du serveur dans le programme)
;	pour copier le kit, ensuite: 
;		$ r psicopy_load
;		From: <adresse DTE>\<specif VMS du kit>
;		To: []
;
	.macro check,?l
	blbs	r0,l
	brw	out
l:	.endm
fab:	$FAB	FNM=<PSICOPY_load.EXE>,FAC=PUT,RFM=FIX,MRS=512,ALQ=160,DEQ=50
rab:	$RAB	FAB=fab,rbf=buffer,rsz=512
ncb:	.word	1$-.,1
	.ascic	/099999999999999/	; 	>>> the server DTE address <<<
1$:	.word	ncbd-.,5
	.ascic	/PSICOPY Boot/
ncbd:	.long	.-ncb,ncb
iosb:	.ascid	/NWA0:/
buffer:	.blkb	512
chan:	.word	0
	$ASSIGN_S	devnam=iosb,chan=chan
	check
	$QIOW_S	chan=chan,func=#IO$_ACCESS,iosb=iosb,p2=#ncbd
	bsbw	cheknet
	movw	#5121,r0
	bsbb	writnet
	bsbw	readnet
	blbs	r1,1$
	brb	proto
1$:	check
	moval	buffer+8,-(sp)
	movzwl	buffer+6,-(sp)
	pushl	sp
	calls	#1,G^LIB$PUT_OUTPUT
	movq	(sp)+,r0
	$CREATE	fab=fab
	check
	$CONNECT	rab=rab
11$:	check
	bsbb	readnet
	blbs	r1,done
	$PUT	rab=rab
	brb	11$
proto:	movzwl	#SS$_PROTOCOL,r0
out:	$EXIT_S r0
done:	cmpl	r0,#SS$_ENDOFFILE
	beql	3$
	check
	brb	proto
3$:	movzwl	#2651,R0
	bsbb	writnet
	ret
writnet:movw	r0,buffer+4
	$QIOW_S	chan=chan,func=#IO$_WRITEVBLK!IO$M_QUALIFIED,iosb=iosb,-
		P1=buffer, P2=#6
cheknet:check
	movzwl	iosb,r0
	check
	rsb
readnet:$QIOW_S chan=chan,func=#IO$_READVBLK,iosb=iosb,p1=buffer,p2=#512
	bsbb	cheknet
	movl	buffer,r0
	extzv	#1,#1,iosb+4,r1
	rsb
	.end	chan