ignorecase on
tabstop 3
resettoggle 20    # cursor on space or eol?
resettoggle 21    # start block selected?
resettoggle 24    # insert buffer exists?
resettoggle 25    # Gold toggle

map `nk(' (ifelse 25 (resettoggle 25) (settoggle 25))         # gold/reset gold
map `nk)' (resettoggle 25 newwindow newfile s:adam.keys)      # help
map `nk/' (ifelse 25 (resettoggle 25 next) (escimm (find )))  # find/find next
map `nk*' (ifelse 25 (resettoggle 25 escimm (execute ) iconify) (escimm ()))
                                                              # do CLI/do DME
map `nk0' (resettoggle 25 wright)                             # move by word
map `nk1' (resettoggle 25 ifelse r (join) (del))              # del char
map `nk2' (resettoggle 25 ifelse r (join) (c-f1 while !20 (del c-f1) cs-f1 while 20 (del cs-f1))
                                                              # del word/undel word
map `nk3' (ifelse 25 (remeol resettoggle 25) (deline first))  # del line/del eol
map `nk4' (ifelse 25 (ping 1 resettoggle 25) (ifelse 21 (unblock resettoggle 21) (block settoggle 21)))
                                                              # select/set mark
map `nk5' (ifelse 25 (if 21 (block ping 2 pong 1 bmove pong 2 resettoggle 21) resettoggle 25) (if 21 (block bsave t:paste bdelete settoggle 24 resettoggle 21)))
                                                              # remove/move to mark
map `nk6' (ifelse 25 (c-nk6) (cs-nk6))                        # append/copy to mark
map `c-nk6' (if 21 (block ping 2 pong 1 bcopy pong 2 unblock) resettoggle 25 resettoggle 21)
                                                              ## copy to mark
map `cs-nk6' (if 21 (block bsave t:paste1 execute (rename t:paste t:paste0) execute (join t:paste0 t:paste1 as t:paste) bdelete resettoggle 21)))
                                                              ## append
map `nk7' (ifelse 25 (top first resettoggle 25) (repeat 11 (up) if r last))
                                                              # prev screen/top
map `nk8' (ifelse 25 (bottom first resettoggle 25) (repeat 11 (down) if r last))
                                                              # next screen/bottom
map `nk9' (ifelse 25 (c-f9 resettoggle 25) (cs-f9))           # cap word-range/lower word-range
map `nk.' (resettoggle 25 ifelse r (down last) last)          # eol
map `nk-' (resettoggle 25 undeline down)                      # undelete line
map `nk+' (ifelse 25 (pong 1 resettoggle 25) (if 24 (insfile t:paste)))
                                                              # paste/goto mark
map `enter' (ifelse 25 (reformat resettoggle 25) (split first downadd))
                                                              # return/fill

##  Function keys -- note ctrl/shift function keys used by other commands ##

# full screen this window
map `f1' (resize 77 23)
# cf1 = if cursor is on space or eol set 20 else reset it
map `c-f1' (resettoggle 20 if c=32 (settoggle 20) if r (settoggle 20))
# csf1 = if cursor is on space set 20 else reset it
map `cs-f1' (resettoggle 20 if c=32 (settoggle 20))
# two windows; get newfile for second window
map `f2' (resize 77 11 openwindow +0+100+640+100 escimm (newfile ))
# source dme command
map `s-f2' (unblock block block bsource down first)
map `f3' (iconify)
map `f5' (quit)
# replace
map `f6' (escimm `findr ')
# replace next
map `s-f6' (nextr)
# cf6 = lowercase this word
map `c-f6' (right wleft resettoggle 20 while !20 (if cu (tlate +32) right c-f1) wright)
# csf6 = uppercase this word
map `cs-f6' (rigth wleft resettoggle 20 while !20 (if cl (tlate -32) right c-f1) wright)
# repolace all
map `f7' (repeat -1 nextr)
# insert file
map `f9' `escimm `insfile ''
# get file
map `s-f9' `escimm `newfile ''
# capitalize selected block or word
map `c-f9' (ifelse 21 (goto start while cb (c-f6 if r (return)) unblock) (c-f6))
# lowercase selected block or word
map `cs-f9' (ifelse 21 (block goto start while cb (cs-f6 if r (return)) unblock) (cs-f6))
map `f10' `saveold quit'
map `s-f10' `escimm `saveas ''


map ` ' `ifelse x<80 (( )) (enter)'                # space.. wrap if past 80
map `return' `enter'                               # insert return
map `c-return' `( ) left tlate 10 right'           # insert ^J
map `c-tab' `( ) left tlate 9 right'               # insert ^I
map `bs' `ifelse l `up last join if !l `del'' bs'  # del left.. join if first col
map `down' `down if r last'                        # down (not past eol)
map `up' `up if r last'                            # up (not past eol)
map `del' `first'                                  # start of line
map `c-a' `insertmode toggle'                      # toggle insert/overstrike
map `c-b' `recall'                                 # recall command
map `c-l' `( ) left tlate 12 right'                # insert ^L
map `c-u' `while !l bs'                            # delete to start of line
map `c-v' `escimm (tlate )'                        # insert ascii character
map `c-z' `f10'                                    # save exit
map `help' `iconify'
map `s-esc' `tlate 27'                             # insert <esc>

menuadd File Quit quit
menuadd File Get-File s-f9
menuadd File Include-File f9
menuadd File Save f10
menuadd File Save-As s-f10