[tickler]

$ on warning then exit
$ if p1 .eqs. "" then write sys$output -
"Enter a VMS date (like '5-SEP') or upcoming weekday (like 'THURS') or 'HELP'"
$ if p1 .eqs. "" then inquire p1 "_$ reminder date"
$ if f$edit( p1 , "trim,upcase" ) .eqs. "HELP" then goto helpstuff
$ daylist = "SUN,MON,TUE,WED,THU,FRI,SAT,SUN,MON,TUE,WED,THU,FRI,"
$ sublist = f$extract( f$locate( f$extract( 0,3, f$edit( -
     f$cvtime("tomorrow",,"weekday"), "upcase" )), daylist ), 28, daylist )
$ daysoff = f$locate(f$extract(0,3,f$edit(p1,"trim,upcase")),",,,,"+sublist)/4
$ if daysoff .le. 7 then p1 = f$cvtime("+''daysoff'-","absolute","date")
$ tickdir = "''f$trnlnm("sys$login")'" - "]" + ".TICKLER]"
$ if f$search("sys$login:tickler.dir") .eqs. "" then create /directory 'tickdir'
$ mailfile = tickdir + "''f$cvtime(p1,,"DATE")'.memo"
$ procname = "''f$environment("procedure")'"
$ utildir = f$parse( procname,,,"DEVICE") + f$parse( procname,,,"DIRECTORY")
$ define/user sys$input sys$command 
$ define/user utildir 'utildir'
$ resubmit = f$search(mailfile)
$ if p2 .eqs. "" 
$ then 
$ 	edit/command=utildir:tickler.edt 'mailfile'
$ 	if resubmit .nes. "" then purge 'mailfile'
$ else
$ 	if resubmit .nes. "" then append 'p2' 'mailfile'
$ 	if resubmit .eqs. "" then copy 'p2' 'mailfile'
$ endif
$ if resubmit .eqs. "" 
$ then
$ 	define/user utildir 'utildir'
$ 	submit/nolog/queue=sys$batch/after='p1' -
		utildir:tickler_job/param='mailfile'
$ endif
$ exit
$helpstuff:
$ type sys$input

=

TICKLER.COM  by Al Beer

This command procedure lets you prepare a 'tickler-file' type reminder to be 
received in your VMS MAIL on the desired day.  MAIL will notify you of your 
message when you log in.  The reminder can be updated until the day it is sent.
In your LOGIN.COM, create a command symbol to invoke the tickler:

$ TIC*KLER :== @SYS$LOGIN:TICKLER

Prepare messages by typing

         $ TICKLER TOMORROW              to be reminded tomorrow
         $ TICKLER FRIDAY                to be reminded this coming Friday
         $ TICKLER 3-Nov                 to be reminded 11/03 this year
         $ TICKLER 3-Nov-1992            to be reminded 11/03/92
         $ TICKLER <date> <filename>     to use text in a file as a reminder
         $ TICKLER HELP                  to see this message
         $ TICKLER                       to be prompted for a date

You will be dropped into EDT and shown any existing reminder for the specified
day.  Quit if no changes are needed; otherwise, update the reminder as desired
and exit normally. The reminder file will be stored in your [username.TICKLER]
subdirectory.  It will be deleted the day you are 'tickled'. 

=

[tickler_job.com]

$ mail 'p1' 'f$getjpi("","USERNAME" ) /subject="Reminder for today"
$ delete 'p1';