define    verb  iufingerd
image     sys$nowhere:[nobody]iufingerd.exe

qualifier debug,
          negatable

qualifier fao,
          value(required),
          nonnegatable

qualifier header,
          value(type=header_options),
          negatable

qualifier home_directory,
          negatable

qualifier host_cache,
          value(required, list, type=cache_options),
          nonnegatable

qualifier jpi,
          value(required, list, type=jpi_options),
          nonnegatable

qualifier last_login,
          negatable

qualifier mail_check,
          negatable

qualifier plan,
          value(required, list, type=$file),
          negatable

qualifier port,
          value(required, type=$number),
          nonnegatable

qualifier project,
          value(required, list, type=$file),
          negatable

qualifier purge_interval,
          value(required, type=$number),
          nonnegatable

qualifier resolve_addresses,
          negatable

qualifier rfc931,
          value(list, type=rfc931_options),
          negatable

qualifier sort,
          value(list, type=sort_options),
          negatable

qualifier time_format,
          value(required, type=time_options),
          nonnegatable

qualifier title,
          value(required),
          negatable

qualifier user_cache,
          value(required, list, type=cache_options),
          nonnegatable

disallow (fao and not jpi) or (jpi and not fao) or (header.systat and not sort)

define type cache_options
  keyword size,
          value(required, type=$number)
  keyword ttl,
          value(required, type=$number)

define type sort_options
  keyword position,
          value(required, type=$number)
  keyword size,
          value(required, type=$number)

define type rfc931_options
  keyword timeout,
          value(required, type=$number)

define type jpi_options
  keyword imagname
  keyword logintim
  keyword pid
  keyword prcnam
  keyword remote
  keyword terminal
  keyword username
  keyword uafowner

define type time_options
  keyword numeric
  keyword text

define type header_options
  keyword systat