module nm$dcl

!++
! DCL definitions for Nmail utility commands
! (Implementors note: the keywords which make up the actual commands
!  as typed by the user are shown in upper case, and can be freely
!  changed. Only these keywords, and the prompts, are visible to the
!  user. Labels assigned to syntactic elements are referred to by the
!  Nmail code and therefore must not be changed).
!--


!
! define the command "verb" and a few assorted keywords
!
define verb NMAIL
    image nm$queman
    parameter p1, value(type=command,required), prompt="Command"
    noqualifiers

define type command
    keyword SHOW, syntax=show
    keyword STOP, syntax=stop 
    keyword START, syntax=start
    keyword ANALYZE, syntax=analyze
    keyword CANCEL, syntax=cancel_job, label=cancel_job
    keyword RELEASE, syntax=release_job, label=release_job

!
! nmail show <something>
!
define syntax show
    parameter p1, value(type=command,required)
    parameter p2, value(type=showtype,required), prompt="What"

define type showtype
    keyword QUEUE, syntax=show_queue, label=show_queue

!
! nmail show queue [/entry=nnn] [/brief|/full] [/status=xxx] [/all|/user=xxx] [/output=xxx]
!
define syntax show_queue
    parameter p1, value(type=command,required)
    parameter p2, value(type=showtype,required)
    qualifier BRIEF, nonnegatable, label=brief
    qualifier FULL, nonnegatable, label=full
    qualifier STATUS, nonnegatable, value(required,type=showstatus,list), label=status
    qualifier ALL, nonnegatable, label=all
    qualifier USER, nonnegatable, value(required), label=user
    qualifier ENTRY, nonnegatable, value(required,type=$number), label=entry
    qualifier OUTPUT, nonnegatable, value(required,type=$outfile), label=output
    disallow brief and full
    disallow all and user
    disallow all and entry

define type showstatus
    keyword UNSENT, label=st_unsent
    keyword SENT, label=st_sent
    keyword FAILED, label=st_failed
    keyword EXPIRED, label=st_expired
    keyword CANCELLED, label=st_cancelled
    
!
! nmail cancel <entry> [/return] [/user=xxx] [/log] [/reason="xxx"]
!                                              
define syntax cancel_job
    parameter p1, value(type=command,required)
    parameter p2, value(type=$number,required), label=entry, prompt="Entry"
    qualifier USER, nonnegatable, value(required), label=user
    qualifier RETURN, negatable, default, label=return
    qualifier REASON, negatable, value(required), label=reason
    qualifier LOG, negatable, label=log
    disallow reason and neg return

!
! nmail release <entry> [/log]
!
define syntax release_job
    parameter p1, value(type=command,required)
    parameter p2, value(type=$number,required), label=entry, prompt="Entry"
    qualifier USER, nonnegatable, value(required), label=user
    qualifier LOG, negatable, label=log

!
! nmail stop <something>
!
define syntax stop
    parameter p1, value(type=command,required)
    parameter p2, value(type=stoptype,required), prompt="What"

define type stoptype
    keyword QUEUE, syntax=stop_queue, label=stop_queue 

!
! nmail stop queue [/oknone] [/delete] [/log]
!
define syntax stop_queue
    parameter p1, value(type=command,required)
    parameter p2, value(type=stoptype,required)
    qualifier OKNONE, negatable, label=oknone
    qualifier DELETE, negatable, label=delete
    qualifier LOG, negatable, label=log
                                   
!
! nmail start <something>
!
define syntax start
    parameter p1, value(type=command,required)
    parameter p2, value(type=starttype,required), prompt="What"

define type starttype
    keyword QUEUE, syntax=start_queue, label=start_queue 

!
! nmail start queue [/log]
!
define syntax start_queue
    parameter p1, value(type=command,required)
    parameter p2, value(type=starttype,required)
    qualifier LOG, negatable, label=log
                                   
!
! nmail analyze <something>
!
define syntax analyze
    parameter p1, value(type=command,required)
    parameter p2, value(type=analyzetype,required), prompt="What"

define type analyzetype
    keyword QUEUE, syntax=analyze_queue, label=analyze_queue

!
! nmail analyze queue [/repair] [/confirm] [/hold] [/return] [/reason="xxx"] [/before=date] [/since=date]
!
define syntax analyze_queue
    parameter p1, value(type=command,required)
    parameter p2, value(type=analyzetype,required)
    qualifier REPAIR, negatable, label=repair
    qualifier CONFIRM, negatable, default, label=confirm
    qualifier RETURN, negatable, label=return
    qualifier REASON, negatable, value(required), label=reason
    qualifier HOLD, negatable, label=hold
    qualifier BEFORE, value(type=$datetime), label=before
    qualifier SINCE, value(type=$datetime), label=since
    disallow confirm and not repair
    disallow return and not repair
    disallow hold and not repair
    disallow reason and not return

!
! end of nmail command definitions
!