!+
! TITLE:  	WCP_CLD
!
! FACILITY: 	WATCHER
!
! ABSTRACT: 	Command language definitions for Watcher Control Program.
!
! AUTHOR:   	M. Madison
!   	       	COPYRIGHT © 1993, 1994  MADGOAT SOFTWARE.
!   	    	ALL RIGHTS RESERVED.
!
! MODIFICATION HISTORY:
!
!   01-SEP-1989	V1.0	Madison	    Initial coding.
!   19-JAN-1990	V1.0-1	Madison	    Add /GROUP to WATCH.
!   20-MAR-1990	V1.0-2	Madison	    Add SHUTDOWN, RESET commands.
!   11-APR-1990	V1.1-3	Madison	    Add thresholds on measurements.
!   20-APR-1990	V1.1-4	Madison	    Add missing SHOW DECWINDOWS.
!   22-MAR-1991	V1.2	Madison	    Add MULTIWARN support.
!   07-APR-1992	V1.3	Madison	    Add NOACTION, IMAGE support.
!   03-FEB-1993	V1.4	Madison	    Add INSWAP, FORCE_EXIT support.
!-
MODULE WCP_CLD
IDENT "V1.4"

DEFINE TYPE MEASURE_KWDS
    KEYWORD CPU, NONNEGATABLE, VALUE (DEFAULT="0", TYPE=$NUMBER)
    KEYWORD TERMINAL_IO, NONNEGATABLE, VALUE (DEFAULT="0", TYPE=$NUMBER)
    KEYWORD PROCESS_IO, NONNEGATABLE, VALUE (DEFAULT="0", TYPE=$NUMBER)

DEFINE TYPE SET_OPTIONS
    KEYWORD INTERVAL, VALUE (REQUIRED, TYPE=$DELTATIME)
    KEYWORD EVENT_LOG, NEGATABLE, SYNTAX=SET_EVENT
    KEYWORD DAYS, SYNTAX=SET_DAYS
    KEYWORD WATCH_DEFAULT SYNTAX=SET_WATCH
    KEYWORD BELL, NEGATABLE
    KEYWORD DEBUG, NEGATABLE, VALUE (DEFAULT="7")
    KEYWORD VERIFY, NEGATABLE
    KEYWORD DECWINDOWS, NEGATABLE
    KEYWORD MULTIWARN, NEGATABLE, SYNTAX=SET_MULTIWARN
    KEYWORD ACTION, NEGATABLE
    KEYWORD INSWAP, NEGATABLE

DEFINE TYPE SHOW_OPTIONS
    KEYWORD WATCH
    KEYWORD EXCLUDE
    KEYWORD EVENT_LOG
    KEYWORD DAYS
    KEYWORD DECWINDOWS
    KEYWORD MULTIWARN
    KEYWORD OVERRIDE
    KEYWORD INTERVAL
    KEYWORD BELL
    KEYWORD DEBUG
    KEYWORD FILE
    KEYWORD ACTION
    KEYWORD INSWAP
    KEYWORD DEFAULTS	    ! SET WATCH settings + SHOW DAYS
    KEYWORD GLOBALS 	    ! SHOW EVENT,INTERVAL,BELL,DEBUG,ACTION
    KEYWORD ALL

DEFINE TYPE PRIV_KWDS
    KEYWORD CMKRNL
    KEYWORD CMEXEC
    KEYWORD SYSNAM
    KEYWORD GRPNAM
    KEYWORD ALLSPOOL
    KEYWORD DETACH
    KEYWORD DIAGNOSE
    KEYWORD LOG_IO
    KEYWORD GROUP
    KEYWORD ACNT
    KEYWORD PRMCEB
    KEYWORD PRMMBX
    KEYWORD PSWAPM
    KEYWORD ALTPRI
    KEYWORD SETPRV
    KEYWORD TMPMBX
    KEYWORD WORLD
    KEYWORD MOUNT
    KEYWORD OPER
    KEYWORD EXQUOTA
    KEYWORD NETMBX
    KEYWORD VOLPRO
    KEYWORD PHY_IO
    KEYWORD BUGCHK
    KEYWORD PRMGBL
    KEYWORD SYSGBL
    KEYWORD PFNMAP
    KEYWORD SHMEM
    KEYWORD SYSPRV
    KEYWORD BYPASS
    KEYWORD SYSLCK
    KEYWORD SHARE
    KEYWORD UPGRADE
    KEYWORD DOWNGRADE
    KEYWORD GRPPRV
    KEYWORD READALL
    KEYWORD SECURITY

DEFINE TYPE OPC_KWDS
    KEYWORD CENTRAL
    KEYWORD PRINTER
    KEYWORD TAPES
    KEYWORD DISKS
    KEYWORD DEVICES
    KEYWORD CARDS
    KEYWORD NETWORK
    KEYWORD CLUSTER
    KEYWORD SECURITY
    KEYWORD OPER1
    KEYWORD OPER2
    KEYWORD OPER3
    KEYWORD OPER4
    KEYWORD OPER5
    KEYWORD OPER6
    KEYWORD OPER7
    KEYWORD OPER8
    KEYWORD OPER9
    KEYWORD OPER10
    KEYWORD OPER11
    KEYWORD OPER12

DEFINE TYPE DAY_KWDS
    KEYWORD PRIMARY, VALUE (LIST)
    KEYWORD SECONDARY, VALUE (LIST)
    KEYWORD MONDAY, VALUE (LIST)
    KEYWORD TUESDAY, VALUE (LIST)
    KEYWORD WEDNESDAY, VALUE (LIST)
    KEYWORD THURSDAY, VALUE (LIST)
    KEYWORD FRIDAY, VALUE (LIST)
    KEYWORD SATURDAY, VALUE (LIST)
    KEYWORD SUNDAY, VALUE (LIST)

DEFINE TYPE DOW_KWDS
    KEYWORD MONDAY
    KEYWORD TUESDAY
    KEYWORD WEDNESDAY
    KEYWORD THURSDAY
    KEYWORD FRIDAY
    KEYWORD SATURDAY
    KEYWORD SUNDAY

DEFINE VERB WATCH
    ROUTINE CMD_WATCH
    PARAMETER P1, LABEL=DEVICE, PROMPT="Device" VALUE (REQUIRED)
    QUALIFIER ACCPORNAM, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER MEASURE, NONNEGATABLE, VALUE (REQUIRED, LIST, TYPE=MEASURE_KWDS)
    QUALIFIER WARNING, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER DISCONNECT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER LOGOUT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER FORCE_EXIT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER GROUP, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER DELETE, NONNEGATABLE
    DISALLOW (DELETE AND (MEASURE OR WARNING OR DISCONNECT OR LOGOUT OR
    	FORCE_EXIT)) OR ANY2 (DISCONNECT, LOGOUT, FORCE_EXIT)

DEFINE VERB EXCLUDE
    ROUTINE CMD_EXCLUDE
    PARAMETER P1, LABEL=USER, PROMPT="Username", VALUE (REQUIRED, LIST)
    QUALIFIER PRIVILEGES, NONNEGATABLE,
    	VALUE (REQUIRED, LIST, TYPE=PRIV_KWDS)
    QUALIFIER HOLDING, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER UIC, NONNEGATABLE, VALUE (REQUIRED,TYPE=$UIC)
    QUALIFIER TERMINAL, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER ACCPORNAM, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER DURING, NONNEGATABLE, VALUE (REQUIRED, LIST, TYPE=DAY_KWDS)
    QUALIFIER IMAGE, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER DELETE, NONNEGATABLE

DEFINE VERB OVERRIDE
    ROUTINE CMD_OVERRIDE
    PARAMETER P1, LABEL=USER, PROMPT="Username", VALUE (REQUIRED, LIST)
    QUALIFIER PRIVILEGES, NONNEGATABLE,
    	VALUE (REQUIRED, LIST, TYPE=PRIV_KWDS)
    QUALIFIER HOLDING, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER UIC, NONNEGATABLE, VALUE (REQUIRED,TYPE=$UIC)
    QUALIFIER TERMINAL, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER ACCPORNAM, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER DURING, NONNEGATABLE, VALUE (REQUIRED, LIST, TYPE=DAY_KWDS)
    QUALIFIER IMAGE, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER MEASURE, NONNEGATABLE, VALUE (REQUIRED, LIST, TYPE=MEASURE_KWDS)
    QUALIFIER WARNING, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER LOGOUT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER DISCONNECT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER FORCE_EXIT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER DELETE, NONNEGATABLE
    DISALLOW ANY2 (DISCONNECT, LOGOUT, FORCE_EXIT)

DEFINE VERB SET
    ROUTINE CMD_SET
    PARAMETER P1, LABEL=SET_OPT, PROMPT="Set_option",
    	VALUE (REQUIRED, TYPE=SET_OPTIONS)

DEFINE SYNTAX SET_EVENT
    ROUTINE CMD_SET_EVENT
    QUALIFIER OPERATOR, VALUE (REQUIRED, LIST, TYPE=OPC_KWDS)
    QUALIFIER FILE, VALUE (REQUIRED, TYPE=$FILE)

DEFINE SYNTAX SET_DAYS
    ROUTINE CMD_SET_DAYS
    QUALIFIER PRIMARY, VALUE (REQUIRED, LIST, TYPE=DOW_KWDS)
    QUALIFIER SECONDARY, VALUE (REQUIRED, LIST, TYPE=DOW_KWDS)
    DISALLOW (PRIMARY AND SECONDARY)

DEFINE SYNTAX SET_WATCH
    ROUTINE CMD_SET_WATCH
    QUALIFIER WARNING, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER DISCONNECT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER LOGOUT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER FORCE_EXIT, NEGATABLE, VALUE (TYPE=$DELTATIME)
    QUALIFIER MEASURE, NONNEGATABLE, VALUE (REQUIRED, LIST, TYPE=MEASURE_KWDS)
    DISALLOW ANY2 (LOGOUT, DISCONNECT, FORCE_EXIT)

DEFINE SYNTAX SET_MULTIWARN
    ROUTINE CMD_SET_MULTIWARN
    QUALIFIER INTERVAL, NEGATABLE, VALUE (TYPE=$DELTATIME)

DEFINE VERB SAVE
    ROUTINE CMD_SAVE
    PARAMETER P1, LABEL=FILESPEC, VALUE (TYPE=$FILE)

DEFINE VERB EXIT
    ROUTINE CMD_EXIT

DEFINE VERB QUIT
    ROUTINE CMD_QUIT

DEFINE VERB HELP
    ROUTINE CMD_HELP
    PARAMETER P1, LABEL=HELP_REQUEST, VALUE (TYPE=$REST_OF_LINE)

DEFINE VERB SHOW
    ROUTINE CMD_SHOW
    PARAMETER P1, LABEL=SHOW_OPT, PROMPT="Show_option",
    	VALUE (REQUIRED, TYPE=SHOW_OPTIONS, LIST)
    QUALIFIER OUTPUT, VALUE (TYPE=$FILE, REQUIRED)
    QUALIFIER COMMAND

DEFINE VERB SHUTDOWN
    ROUTINE CMD_SHUTDOWN
    NOPARAMETERS
    NOQUALIFIERS

DEFINE VERB RESET
    ROUTINE CMD_RESET
    NOPARAMETERS
    NOQUALIFIERS