$! make libz under VMS
$! written by Jean-Francois Pieronne <jf.pieronne@laposte.net>
$!
$ proc = f$environment("PROCEDURE")
$ cur_dev = f$parse(proc,,,"DEVICE","SYNTAX_ONLY")
$ cur_dir = f$parse(proc,,,"DIRECTORY","SYNTAX_ONLY")
$ set default 'cur_dev''cur_dir'
$
$ if f$getsyi("ARCH_TYPE").gt. 1
$ then
$     if p1 .eqs. ""
$     then
$         @'proc' long
$         @'proc' nolong
$         exit
$     endif
$ endif
$
$ if f$getsyi("ARCH_TYPE").gt. 1 
$ then
$   cflags = "/prefix=all/names=(as_is)/float=ieee/accept=novaxc_keywords"
$   version = F$GETSYI("VERSION")
$   version_number = F$EXTRACT(1,3,version)
$   if f$extract(0,1,version) .eqs. "V" .or. f$extract(0,1,version) .eqs. "T"
$   then
$     if (version_number .GES. "7.2")
$      then
$          cflags = cflags + "/def=(_LARGEFILE)"
$      endif
$     if p1 .eqs. "LONG"
$     then
$         cflags = cflags + "/pointer=long"
$     endif
$   endif
$ else
$   cflags = "/prefix=all/accept=novaxc_keywords"
$ endif
$
$ cc 'cflags' adler32.c
$ cc 'cflags' compress.c
$ cc 'cflags' crc32.c
$ cc 'cflags' deflate.c
$ cc 'cflags' gzio.c
$ cc 'cflags' infback.c
$ cc 'cflags' inffast.c
$ cc 'cflags' inflate.c
$ cc 'cflags' inftrees.c
$ cc 'cflags' trees.c
$ cc 'cflags' uncompr.c
$ cc 'cflags' zutil.c
$ libr/create libz.olb -
	adler32, -
	compress, -
	crc32, -
	deflate, -
	gzio, -
	infback, -
	inffast, -
	inflate, -
	inftrees, -
	trees, -
	uncompr, -
	zutil
$
$ cc 'cflags' example
$ link example.obj,libz.olb/lib
$ cc 'cflags' minigzip
$ link minigzip.obj,libz.olb/lib
$
$ if f$getsyi("ARCH_TYPE").gt. 1
$ then
$     link/share=libzshr-1_2_1.exe libz-1_2_1.opt/options
$     if p1 .eqs. "LONG"
$     then
$         rename libzshr-1_2_1.exe libzshr64-1_2_1.exe
$         rename libz.olb libz64.olb
$         rename example.exe example64.exe
$         rename minigzip.exe minigzip64.exe
$     else
$         rename libzshr-1_2_1.exe libzshr32-1_2_1.exe
$         rename libz.olb libz32.olb
$         rename example.exe example32.exe
$         rename minigzip.exe minigzip32.exe
$     endif
$ endif
$
$ delete *.obj;*
$
$ exit